太閤立志伝５イベントソース
//自動献上イベントVer1.2

//更新履歴
//1.1 石山本願寺の処理がおかしいのを修正
//1.1 加算値に少し幅を持たせた
//1.2 54行目の「何度でも｜ひかえめ」の「ひかえめ」を消去した（報告ありがとうございます）

//変数ａ　経過日数関連加算係数
//変数ｂ/ｅ　城データ抽出
//変数ｃ/ｆ　加算数計算結果
//変数ｄ/ｇ  加算後城データ格納値
//変数ｒ　係数加算用ランダム値は(0〜2)


//加算事項
//薩摩内城処理(鉄砲150xN)
//摂津石山処理（本願寺+鈴木が当主の時のみ 鉄砲50xN）
//泉州岸和田/堺処理(支配力5000以上 大砲2xN 鉄砲200xN）
//紀州雑賀処理（鉄砲100xN)
//近江今浜処理(鉄砲100xN)
//筑前立花山(博多)処理(支配力3000以上　軍資金10000xN)
//肥前平戸(支配力3000以上　大砲2xN 鉄砲200xN)
//東北地方(各城　軍馬200xN)

//約１年経過するごとに加算される値が年数分増えていきます。
//Ver1.1より加算係数が+1〜+3されます。
//たとえば５年目だと基本値に　5+1+(0〜2)=6〜8倍加算される(はず)。



チャプター:{

//フラグ設定イベント
イベント:他大名時加算するか判別イベント{
属性:一度だけ
発生契機:ゲームスタート時
スクリプト:{
	ナレーション:[[産出地加算イベント設定]]
	ナレーション可否選択:[[産出地が自分の勢力以外の時に物資が献上される様にしますか？]]
		分岐:(可){			
			更新:(イベントフラグ::他城主時献上)(成立)
			ナレーション:[[他の勢力の場合でも献上される様になります]]
			}
		分岐:(否){
			更新:(イベントフラグ::他城主時献上)(不成立)
			ナレーション:[[他勢力の場合、物資が献上される事はありません]]
			}
		}
}
}

//物資加算イベント
イベント:産出地加算{
属性:何度でも
発生契機:毎月処理の最後
発生条件:{
			調査:(主人公.身分)>=(城主)
	ＯＲ調査:{
			調査:(状況::月)==(3)
			調査:(状況::月)==(6)
			調査:(状況::月)==(9)
			調査:(状況::月)==(12)
		}
	}

スクリプト:{
代入ａ:(状況::ゲーム経過日数)
代入ａ:(ａ)/(365)
代入ａ:(ａ)+(1)
代入ｒ:(Ｒｎｄ)%(3)
代入ａ:(ａ)+(ｒ)
//上は初期変数設定


//　以下薩摩内城処理(鉄砲150xN)
	代入大名家Ａ:(主人公.所属大名家)
	調査:(城::内.所属大名家)==(大名家Ａ)
		代入ｂ:(城::内.鉄砲)
		代入ｃ:(ａ)*(150)
		代入ｄ:(ｂ)+(ｃ)
		分岐:(真){
				更新:(城::内.鉄砲)(ｄ)
				ナレーション:[[内城にて鉄砲が<ｃ>丁献上されました！]]
//ナレーション:[[<ａ>、<ｂ>、<ｃ>、<ｄ>、<ｒ>でした。]]
//デバック用
			}
		分岐:(偽){
		調査:(イベントフラグ::他城主時献上)==(成立)
			分岐:(真){
				更新:(城::内.鉄砲)(ｄ)
				}
			分岐:(偽){
				}
			}

//　以下摂津石山処理（本願寺+鈴木のみ 鉄砲50xN）
	ＯＲ調査:{
			調査:(城::石山本願.所属大名家)==(本願寺教如)
			調査:(城::石山本願.所属大名家)==(本願寺顕如)
			調査:(城::石山本願.所属大名家)==(本願寺准如)
			調査:(城::石山本願.所属大名家)==(鈴木佐太夫)
			調査:(城::石山本願.所属大名家)==(鈴木重朝)
			調査:(城::石山本願.所属大名家)==(雑賀孫一)
		}
	分岐:(真){//当主調査の結果
		代入大名家Ａ:(主人公.所属大名家)
		調査:(城::石山本願.所属大名家)==(大名家Ａ)
		代入ｂ:(城::石山本願.鉄砲)
		代入ｃ:(ａ)*(50)
		代入ｄ:(ｂ)+(ｃ)
		分岐:(真){//主人公所属大名家が占拠しているか
				更新:(城::石山本願.鉄砲)(ｄ)
				ナレーション:[[石山本願寺に鉄砲が<ｃ>丁寄進されました]]
			}
		分岐:(偽){//主人公所属大名家が占拠しているか
			調査:(イベントフラグ::他城主時献上)==(成立)
				分岐:(真){
					更新:(城::石山本願.鉄砲)(ｄ)
					}
				分岐:(偽){
					}
			}
		}
	分岐:(偽){//当主調査の結果
		}
		
//泉州岸和田/堺処理(支配力5000以上 大砲2xN 鉄砲200xN）
	代入大名家Ａ:(主人公.所属大名家)
	代入大名家Ｂ:(城::岸和田.所属大名家)
	ＡＮＤ調査:{
		調査:(城::岸和田.所属大名家)==(大名家Ａ)
		調査:(大名家::大名家Ａ.支配力)>=(5000)
		}
		代入ｂ:(城::岸和田.鉄砲)
		代入ｃ:(ａ)*(200)
		代入ｄ:(ｂ)+(ｃ)
		代入ｅ:(城::岸和田.大筒)
		代入ｆ:(ａ)*(2)
		代入ｇ:(ｅ)+(ｆ)
		分岐:(真){
				更新:(城::岸和田.鉄砲)(ｄ)
				更新:(城::岸和田.大筒)(ｇ)
				ナレーション:[[岸和田城にて鉄砲が<ｃ>丁、大筒が<ｆ>門献上されました！]]
			}
		分岐:(偽){
		ＡＮＤ調査:{
			調査:(イベントフラグ::他城主時献上)==(成立)
			調査:(大名家::大名家Ｂ.支配力)>=(5000)
			}
			
			分岐:(真){
				更新:(城::岸和田.鉄砲)(ｄ)
				更新:(城::岸和田.大筒)(ｇ)
				}
			分岐:(偽){
				}
			}

//紀州雑賀処理（鉄砲100xN)
	代入大名家Ａ:(主人公.所属大名家)
	調査:(城::雑賀.所属大名家)==(大名家Ａ)
		代入ｂ:(城::雑賀.鉄砲)
		代入ｃ:(ａ)*(100)
		代入ｄ:(ｂ)+(ｃ)
		分岐:(真){
				更新:(城::雑賀.鉄砲)(ｄ)
				ナレーション:[[雑賀城にて鉄砲が<ｃ>丁献上されました！]]
			}
		分岐:(偽){
		調査:(イベントフラグ::他城主時献上)==(成立)
			分岐:(真){
				更新:(城::雑賀.鉄砲)(ｄ)
				}
			分岐:(偽){
				}
			}

//近江今浜処理(鉄砲100xN)
	代入大名家Ａ:(主人公.所属大名家)
	調査:(城::今浜.所属大名家)==(大名家Ａ)
		代入ｂ:(城::今浜.鉄砲)
		代入ｃ:(ａ)*(100)
		代入ｄ:(ｂ)+(ｃ)
		分岐:(真){
				更新:(城::今浜.鉄砲)(ｄ)
				ナレーション:[[今浜城にて鉄砲が<ｃ>丁献上されました！]]
			}
		分岐:(偽){
		調査:(イベントフラグ::他城主時献上)==(成立)
			分岐:(真){
				更新:(城::今浜.鉄砲)(ｄ)
				}
			分岐:(偽){
				}
			}


//筑前立花山(博多)処理(支配力3000以上　軍資金10000xN)
	代入大名家Ａ:(主人公.所属大名家)
	代入大名家Ｂ:(城::立花山.所属大名家)
	ＡＮＤ調査:{
		調査:(城::立花山.所属大名家)==(大名家Ａ)
		調査:(大名家::大名家Ｂ.支配力)>=(3000)
		}
		代入ｂ:(城::立花山.軍資金)
		代入ｃ:(ａ)*(10000)
		代入ｄ:(ｂ)+(ｃ)
		分岐:(真){
				更新:(城::立花山.軍資金)(ｄ)
				ナレーション:[[立花山城にて軍資金が<ｃ>貫献上されました！]]
			}
		分岐:(偽){
			ＡＮＤ調査:{
				調査:(大名家::大名家Ｂ.支配力)>=(3000)
				調査:(イベントフラグ::他城主時献上)==(成立)
				}
				分岐:(真){
					更新:(城::立花山.軍資金)(ｄ)
					}
				分岐:(偽){
					}
			}
//肥前平戸(支配力3000以上　大砲2xN 鉄砲200xN)
	代入大名家Ａ:(主人公.所属大名家)
	代入大名家Ｂ:(城::平戸.所属大名家)
	ＡＮＤ調査:{
		調査:(城::平戸.所属大名家)==(大名家Ａ)
		調査:(大名家::大名家Ａ.支配力)>=(3000)
		}
		代入ｂ:(城::平戸.鉄砲)
		代入ｃ:(ａ)*(200)
		代入ｄ:(ｂ)+(ｃ)
		代入ｅ:(城::平戸.大筒)
		代入ｆ:(ａ)*(2)
		代入ｇ:(ｅ)+(ｆ)
		分岐:(真){
				更新:(城::平戸.鉄砲)(ｄ)
				更新:(城::平戸.大筒)(ｇ)
				ナレーション:[[平戸城にて鉄砲が<ｃ>丁、大筒が<ｆ>門献上されました！]]
			}
		分岐:(偽){
		ＡＮＤ調査:{
			調査:(イベントフラグ::他城主時献上)==(成立)
			調査:(大名家::大名家Ｂ.支配力)>=(3000)
			}
			
			分岐:(真){
				更新:(城::平戸.鉄砲)(ｄ)
				更新:(城::平戸.大筒)(ｇ)
				}
			分岐:(偽){
				}
			}

//東北地方(各城　軍馬200xN)
	代入大名家Ａ:(主人公.所属大名家)
	コンテナ設定:(城,所在地方,東北)
	調査:(コンテナカウンタ)>(0)
	分岐:(真){
		ループ:{
			コンテナ選択:(城Ａ,先頭)
			代入ｂ:(城Ａ.軍馬)
			代入ｃ:(ａ)*(200)
			代入ｄ:(ｂ)+(ｃ)
			調査:(城Ａ.所属大名家)==(大名家Ａ)
				分岐:(真){
						更新:(城::城Ａ.軍馬)(ｄ)
						ナレーション:[[<城Ａ>城にて軍馬が<ｃ>頭献上されました！]]
					}
				分岐:(偽){
					調査:(イベントフラグ::他城主時献上)==(成立)
					分岐:(真){
						更新:(城Ａ.軍馬)(ｄ)
						}
					分岐:(偽){
						}
					}
			コンテナ選抜:(削る,1)
			調査:(コンテナカウンタ)==(0)
			ブロック脱出:(真)
			}//ループ終わり
		}


}//スクリプト終了
}
}//チャプター終了