太閤立志伝５イベントソース
チャプター:{

//電波Lv3.1

//自宅で一度だけ発生します。
//電波を受信して、嫁候補の所在・ALL90ＯＶＥＲの苗字無しの人
//・存在する女海賊とくの一を知ります……それだけですヽ(´ヮ｀)ﾉ
//嫁候補の所在は独身男性のみになります。
//面識フラグの有無を選択出来るようになりました。
//微修正かけました。

イベント:汎用キャラ探し{
属性:一度だけ｜ひかえめ
発生契機:室内画面表示後(無効,自宅)
発生条件:{
}
スクリプト:{
	代入人物Ａ:(主人公)
		ナレーション選択:[[<人物Ａ>に電波が届いてます\n受信しますか？]]
	選択:([[電波を受信する]],[[人外にはなりたくない]])
	分岐:([[電波を受信する]]){
		ＡＮＤ調査:{
			調査:(人物::主人公.奥さん)==(無効)
			調査:(人物::主人公.性別)==(男)
		}
		分岐:(真){//嫁探し
			ひとりごと選択:[[一人身では何かと不便{だ}な\n候補が何処に居るか探そうか？]]
			選択:([[探す（全員面識フラグなし）]],[[探す（阿国のみ面識なし）]],[[探す（全員面識フラグあり）]],[[探さない]])
			分岐:([[探す（全員面識フラグなし）]]){
				代入ａ:(1)
				代入人物Ｅ:(門番)
				代入人物Ｄ:(門番)
			}
			分岐:([[探す（阿国のみ面識なし）]]){
				代入ａ:(1)
				代入人物Ｅ:(主人公)
				代入人物Ｄ:(門番)
			}
			分岐:([[探す（全員面識フラグあり）]]){
				代入ａ:(1)
				代入人物Ｅ:(主人公)
				代入人物Ｄ:(主人公)
			}
			
			調査:(ａ)==(1)
			分岐:(真){
				代入拠点Ａ:(人物::しづ.所属拠点)
				会話:(しづ,人物Ｅ)[[しづは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::たえ.所属拠点)
				会話:(たえ,人物Ｅ)[[たえは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::すず.所属拠点)
				会話:(すず,人物Ｅ)[[すずは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::つう.所属拠点)
				会話:(つう,人物Ｅ)[[つうは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::はる.所属拠点)
				会話:(はる,人物Ｅ)[[はるは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::さよ.所属拠点)
				会話:(さよ,人物Ｅ)[[さよは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::あや.所属拠点)
				会話:(あや,人物Ｅ)[[あやは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::なつ.所属拠点)
				会話:(なつ,人物Ｅ)[[なつは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::ふみ.所属拠点)
				会話:(ふみ,人物Ｅ)[[ふみは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::みよ.所属拠点)
				会話:(みよ,人物Ｅ)[[みよは<拠点Ａ>に居るようだ]]
				代入拠点Ａ:(人物::出雲の阿国.所属拠点)
				会話:(出雲の阿国,人物Ｄ)[[出雲の阿国は<拠点Ａ>に居るようだ]]}
				
				コンテナ設定:(人物,カテゴリ,武将)
				コンテナ除外:(人物,性別,男)
				コンテナ除外:(人物,出現フラグ,未出現)
				コンテナ除外:(人物,死亡フラグ,死亡)
				//ここから
				条件ループ:(コンテナカウンタ)>(0){
					コンテナ選択:(人物Ａ,先頭)
					代入拠点Ａ:(人物::人物Ａ.所属拠点)
					会話:(人物Ａ,人物Ｅ)[[<人物Ａ>は<拠点Ａ>に居るようだ]]
					コンテナ選抜:(削る,1)
					調査:(コンテナカウンタ)>(0)
					ブロック脱出:(偽)
				}
			}
		}//嫁探し〆
		
		
		//ALL90の苗字無し探し
		ひとりごと選択:[[この世の何処かに\n全ての能力が高い者が居るという\n…何処に居るか探そうか？]]
		選択:([[探す（面識フラグなし）]],[[探す（面識フラグあり）]],[[探さない]])
		分岐:([[探す（面識フラグなし）]]){
			代入ａ:(2)
			代入人物Ｅ:(門番)
		}
		分岐:([[探す（面識フラグあり）]]){
			代入ａ:(2)
			代入人物Ｅ:(主人公)
		}
		
		調査:(ａ)==(2)
		分岐:(真){
			コンテナ設定:(人物,カテゴリ,汎用ライバル)
			コンテナ除外:(人物,死亡フラグ,死亡)
			コンテナ除外:(人物,出現フラグ,未出現)
			//ソートしておくと見つけるのが早いのでソートする
			コンテナソート:(人物,素武力,降順)
			コンテナソート:(人物,素政務,降順)
			コンテナソート:(人物,素知謀,降順)
			コンテナソート:(人物,素魅力,降順)
			コンテナソート:(人物,素統率力,降順)
			代入ｂ:(コンテナカウンタ)
			ループ:{
				コンテナ選択:(人物Ａ,先頭)
				ＡＮＤ調査:{
					調査:(人物::人物Ａ.素武力)>=(90)
					調査:(人物::人物Ａ.素政務)>=(90)
					調査:(人物::人物Ａ.素知謀)>=(90)
					調査:(人物::人物Ａ.素魅力)>=(90)
					調査:(人物::人物Ａ.素統率力)>=(90)
				}
				ブロック脱出:(真)//居たならループ脱出
				コンテナ選抜:(削る,1)
				代入ｂ:(コンテナカウンタ)
				調査:(ｂ)>(0)
				ブロック脱出:(偽)//見つからない場合の永久ループ脱出用
			}
			調査:(ｂ)!=(0)//コンテナ人数チェック
			分岐:(真){//コンテナが1以上なら当該キャラ居たので脱出してきた
				代入拠点Ａ:(人物::人物Ａ.所属拠点)
				会話:(人物Ａ,人物Ｅ)[[<拠点Ａ>に住む<人物Ａ>か]]
			}
			分岐:(偽){//コンテナが0なら当該キャラなかったので脱出してきた
				ひとりごと:[[……死んでこの世に居ない…\nもしくはまだ元服してない……か]]
			}
		}//ALL90の苗字無し探し〆
		
		//くノ一・女海賊探し
		ひとりごと選択:[[この世の住む全ての\nくノ一・女海賊を探そうか？]]
		選択:([[探す（面識フラグなし）]],[[探す（面識フラグあり）]],[[探さない]])
		分岐:([[探す（面識フラグなし）]]){
			代入ａ:(3)
			代入人物Ｅ:(門番)
		}
			分岐:([[探す（面識フラグあり）]]){
			代入ａ:(3)
			代入人物Ｅ:(主人公)
		}
		
		調査:(ａ)==(3)
		分岐:(真){
			コンテナ設定:(人物,カテゴリ,汎用ライバル)
			コンテナ除外:(人物,死亡フラグ,死亡)
			コンテナ除外:(人物,出現フラグ,未出現)
			コンテナ除外:(人物,性別,男)
			調査:(コンテナカウンタ)>(0)
			分岐:(真){
				ループ:{
					コンテナ選択:(人物Ａ,先頭)
					代入ａ:(人物::人物Ａ.人物番号)
					代入拠点Ａ:(人物::人物Ａ.所属拠点)
					会話:(人物Ａ,人物Ｅ)[[<拠点Ａ>に住む<人物Ａ>……\n（人物番号は<ａ>）]]
					コンテナ選抜:(削る,1)
					調査:(コンテナカウンタ)>(0)
					ブロック脱出:(偽)
				}
			}
			分岐:(偽){
				ひとりごと:[[……死んでこの世に一人も居ない…か]]
			}
		}//くノ一・女海賊探し
		
		ひとりごと:[[……こんなところか]]//電波受信終了
	}
	
	分岐:([[人外にはなりたくない]]){
		ひとりごと:[[……止めておこう]]
	}
	
}
}

}