太閤立志伝５イベントソース
//【人生交換】Ver1.01

チャプター:{
イベント:人生交換・交換{
属性:何度でも｜ひかえめ
発生契機:室内画面表示後(無効,民家)
発生条件:{
調査:(イベントフラグ::人生交換・交換済み)==(不成立)
ＯＲ調査:{
	調査:(人物::主人公.身分)>=(城主)
	調査:(人物::主人公.身分)==(頭)
	調査:(人物::主人公.身分)==(頭領)
}
代入人物Ａ:(ＭＰ主人)
調査:(人物::人物Ａ.身分)==(浪人)
調査:(人物::人物Ａ.親密度)>=(90)
調査:(人物::人物Ａ.留守フラグ)==(在宅)
調査:(人物::人物Ａ.病気フラグ)==(健康)
調査:(Ｒｎｄ１００)<(40)
}//条件〆

スクリプト:{

条件ブロック:(人物::主人公.身分)==(大名){
	文字列設定:(文字列Ａ)[[大名]]
}
条件ブロック:(人物::主人公.身分)==(国主){
	文字列設定:(文字列Ａ)[[国主]]
}
条件ブロック:(人物::主人公.身分)==(城主){
	文字列設定:(文字列Ａ)[[城主]]
}
条件ブロック:(人物::主人公.身分)==(頭){
	文字列設定:(文字列Ａ)[[頭]]
}
条件ブロック:(人物::主人公.身分)==(頭領){
	文字列設定:(文字列Ａ)[[頭領]]
}

会話:(主人公,人物Ａ)[[（立身出世を志し\n　<文字列Ａ>となったものの、{一人称}の人生\n　このままで良いものだろうか？）]]
会話:(主人公,人物Ａ)[[（その点、{二人称名前}は自由で羨ましい…）]]
会話可否選択:(主人公,人物Ａ)[[（いっそのこと、{二人称名前}と\n　生活を入れ替えてしまおうか？）]]
分岐:(否){
	ひとりごと:[[（いやいや、何を馬鹿なことを\n　考えているの{だ}…\n　最近疲れているのか……）]]
}
分岐:(可){
	会話:(主人公,人物Ａ)[[{二人称名前}、折り入って相談が{ある}]]
	会話:(人物Ａ,主人公)[[何{です}か？]]
	会話:(主人公,人物Ａ)[[{一人称}と{二人称名前}の人生を\n少しの間でも、交換{しない}か？]]
	会話:(人物Ａ,主人公)[[なんと！？\n浪人の身である{一人称}にとっては\n願ってもない話で{ある}]]
	会話:(人物Ａ,主人公)[[しかし、そのようなことが\n可能{であろう}か？]]
	会話:(主人公,人物Ａ)[[心配{ない}\n問題が起きれば、お互い元の生活に\n戻ればよい{であろう}]]
	会話:(人物Ａ,主人公)[[{二人称名前}がそう{いう２}のであれば\n{一人称}に断る理由は{ない}]]
	会話:(主人公,人物Ａ)[[おお！！\nでは、しばらくの間よろしく頼みます{ぞ}]]

	ＯＲ調査:{
		調査:(人物::主人公.身分)==(大名)
		調査:(人物::主人公.身分)==(頭)
		調査:(人物::主人公.身分)==(頭領)
	}
	分岐:(真){
		人物登用:(人物Ａ,直臣,主人公)
		家督を譲る:(主人公,人物Ａ)
	}
	分岐:(偽){
		代入人物Ｂ:(人物::主人公.所属当主)
		人物登用:(人物Ａ,直臣,人物Ｂ)
		代入城Ｂ:(人物::主人公.所属拠点)
		城主解任:(城Ｂ)
		コンテナ設定:(城,城主,主人公)
		ループ:{
			調査:(コンテナカウンタ)>(0)
			ブロック脱出:(偽)
			コンテナ選択:(城Ａ,先頭)
			城主解任:(城Ａ)
			城主任命:(人物Ａ,城Ａ)
			コンテナ選抜:(削る,1)
		}
		城主任命:(人物Ａ,城Ｂ)
		コンテナ設定:(人物,所属上司,主人公)
		コンテナ絞り込み:(人物,出現フラグ,出現済み)
		ループ:{
			コンテナ選択:(人物Ｃ,先頭)
			ブロック脱出:(偽)
			代入ｚ:(人物::人物Ｃ.武士勲功)
			人物解雇:(人物Ｃ,京の町,出現済み)
			更新:(人物::人物Ｃ.武士勲功)(ｚ)
			人物登用:(人物Ｃ,陪臣,人物Ａ)
			コンテナ選抜:(削る,1)
		}
	}
	代入ｘ:(人物::人物Ａ.人物番号)
	更新:(人物::宇野藤右衛門.忍者勲功)(ｘ)
	更新:(イベントフラグ::人生交換・交換済み)(成立)
	代入町Ａ:(発生拠点)
	人物解雇:(主人公,町Ａ,出現済み)
	外に出す:
}//可〆

}//スクリプト〆
}//イベント〆

イベント:人生交換・復帰{
属性:何度でも｜ひかえめ
発生契機:室内画面表示後(無効,無効)
発生条件:{
調査:(イベントフラグ::人生交換・交換済み)==(成立)
ＯＲ調査:{
	調査:(発生施設)==(城主の間)
	調査:(発生施設)==(忍び屋敷)
	調査:(発生施設)==(海賊屋敷)
}
代入ｐ:(人物::宇野藤右衛門.忍者勲功)
代入人物Ａ:(ＭＰ主人)
代入ｑ:(人物::人物Ａ.人物番号)
調査:(ｑ)==(ｐ)
調査:(人物::人物Ａ.留守フラグ)==(在宅)
調査:(人物::人物Ａ.病気フラグ)==(健康)
}//条件〆

スクリプト:{

代入ｘ:(0)
会話:(人物Ａ,主人公)[[{おお}！　{二人称名前}{ではない}か\n来訪、歓迎{いたす}]]
会話:(人物Ａ,主人公)[[{一人称}に何の用{だ}？]]

ひとりごと可否選択:[[（そろそろ元の生活に戻ろうか？）]]
分岐:(否){
	ひとりごと:[[（まだこのままで良いか…）]]
}

分岐:(可){
	会話:(主人公,人物Ａ)[[{二人称名前}、そろそろ元の生活に戻ろうと\n考えているの{だ}が……]]

	代入ｎ:(人物::人物Ａ.親密度)
	代入ｍ:(人物::人物Ａ.野心)
	調査:(ｎ)>=(ｍ)
	分岐:(真){
		代入ｘ:(1)
		会話:(人物Ａ,公家)[[左様{です}か\n貴重な体験をさせて{もらった}]]
		会話:(主人公,小姓)[[こちらこそ有意義な体験を\nさせて{もらった}]]
	}
	分岐:(偽){
		ＳＥスタート:(暗黒コマンド)
		会話:(人物Ａ,主人公)[[ふっ……]]
		会話:(人物Ａ,小姓)[[せっかく手に入れたこの地位\nむざむざ手放すことが{できよう}か！]]
		会話:(主人公,人物Ａ)[[！！　{二人称名前}！]]
		会話:(人物Ａ,小姓)[[{二人称}にはここで死んでもらおう！！]]

		条件ブロック:(発生施設)==(城主の間){
			個人戦闘:(逃げられない,護衛なし,無効,人物Ａ,無効,無効,無効,無効,城主の間,偽,偽)
			分岐:([[勝利]]){
				会話:(人物Ａ,主人公)[[くっ……]]
			}
			分岐:([[敗北]]){
				会話:(主人公,人物Ａ)[[無念……]]
				武将死亡:(主人公)
			}
		}
		条件ブロック:(発生施設)==(忍び屋敷){
			個人戦闘:(逃げられない,護衛なし,無効,人物Ａ,無効,無効,無効,無効,忍者宅の庭,偽,偽)
			分岐:([[勝利]]){
				会話:(人物Ａ,主人公)[[くっ……]]
			}
			分岐:([[敗北]]){
				会話:(主人公,人物Ａ)[[無念……]]
				武将死亡:(主人公)
			}
		}
		条件ブロック:(発生施設)==(海賊屋敷){
			個人戦闘:(逃げられない,護衛なし,無効,人物Ａ,無効,無効,無効,無効,砂浜,偽,偽)
			分岐:([[勝利]]){
				会話:(人物Ａ,主人公)[[くっ……]]
			}
			分岐:([[敗北]]){
				会話:(主人公,人物Ａ)[[無念……]]
				武将死亡:(主人公)
			}
		}

		ひとりごと選択:[[<人物Ａ>をどうしてくれようか…]]
		
		選択:[[斬首する]][[見逃す]]

		分岐:([[斬首する]]){
			代入ｘ:(2)
			会話:(主人公,人物Ａ)[[{二人称名前}！　覚悟はできているであろうな！！]]
			会話:(人物Ａ,主人公)[[……]]
			会話:(主人公,人物Ａ)[[成敗！！]]
			ＳＥスタート:(刀で斬られる２)
		}
		分岐:([[見逃す]]){
			代入ｘ:(3)
			会話:(主人公,人物Ａ)[[<人物Ａ>！　どことなり失せるがよい！]]
			会話:(人物Ａ,主人公)[[無念……]]
		}
	}//偽〆

	条件ブロック:(人物::主人公.所属勢力タイプ)!=(浪人){
		人物解雇:(主人公,京の町,出現済み)
	}

	ＯＲ調査:{
		調査:(人物::人物Ａ.身分)==(大名)
		調査:(人物::人物Ａ.身分)==(頭)
		調査:(人物::人物Ａ.身分)==(頭領)
	}
	分岐:(真){
		人物登用:(主人公,直臣,人物Ａ)
		家督を譲る:(人物Ａ,主人公)
	}
	分岐:(偽){
		代入人物Ｂ:(人物::人物Ａ.所属当主)
		人物登用:(主人公,直臣,人物Ｂ)
		代入城Ｂ:(人物::人物Ａ.所属拠点)
		城主解任:(城Ｂ)
		コンテナ設定:(城,城主,人物Ａ)
		ループ:{
			調査:(コンテナカウンタ)>(0)
			ブロック脱出:(偽)
			コンテナ選択:(城Ａ,先頭)
			城主解任:(城Ａ)
			城主任命:(主人公,城Ａ)
			コンテナ選抜:(削る,1)
		}
		城主任命:(主人公,城Ｂ)
		コンテナ設定:(人物,所属上司,人物Ａ)
		コンテナ絞り込み:(人物,出現フラグ,出現済み)
		ループ:{
			調査:(コンテナカウンタ)>(0)
			ブロック脱出:(偽)
			コンテナ選択:(人物Ｃ,先頭)
			代入ｚ:(人物::人物Ｃ.武士勲功)
			人物解雇:(人物Ｃ,京の町,出現済み)
			更新:(人物::人物Ｃ.武士勲功)(ｚ)
			人物登用:(人物Ｃ,陪臣,主人公)
			コンテナ選抜:(削る,1)
		}
	}//偽〆

	条件ブロック:(ｘ)==(1){
		代入拠点Ａ:(人物::主人公.所属拠点)
		代入国Ａ:(拠点::拠点Ａ.所属国)
		コンテナ設定:(町,無効,無効)
		コンテナ検索:(町,所属国,国Ａ)
		コンテナ選択:(町Ａ,ポインタ)

		人物解雇:(人物Ａ,町Ａ,出現済み)
	}

	条件ブロック:(ｘ)==(2){
		武将死亡:(人物Ａ)
	}

	条件ブロック:(ｘ)==(3){
		ループ:{
			人物解雇:(人物Ａ,無効,出現済み)
			代入町Ａ:(人物::人物Ａ.所属拠点)
			ＡＮＤ調査:{
				調査:(町::町Ａ.所属国)!=(朝鮮)
				調査:(町::町Ａ.所属国)!=(明)
				調査:(町::町Ａ.所属国)!=(琉球)
				調査:(町::町Ａ.所属国)!=(南蛮)
			}
			ブロック脱出:(真)
			人物登用:(人物Ａ,直臣,無効)
		}
		更新:(人物::人物Ａ.親密度)(0)
	}

	更新:(イベントフラグ::人生交換・交換済み)(不成立)
	外に出す:
}//可〆

}//スクリプト〆
}//イベント〆

}//チャプター〆