太閤立志伝５イベントソース
//れがしぃさん感謝です。フラグ化ありがとうございます
//Ver2.10
//イベント:軍神導入噂話
//イベント:軍神導入
//イベント:軍神０１
//イベント:毘沙門天野戦開始
//イベント:毘沙門天野戦終了
//八板金兵衛の４勲功値が犠牲になります←フラグ化で無問題に
//--------履歴
//2009-08-24:L784 毘沙門天効果->毘沙門天野戦
//2009-08-24:L741 数値保持フラグ初期化処理追加
//--------

チャプター:{
	イベント:軍神導入噂話{
		属性:一度だけ
		発生契機:室内画面表示後(無効,酒場)
		発生条件:{
			調査:(状況::拠点)!=(直江津の町)
			調査:(Ｒｎｄ１００)<(30)
			調査:(イベント::軍神導入)!=(発生済み)
			ＡＮＤ調査:{
				調査:(上杉謙信.死亡フラグ)==(生存)
				ＯＲ調査:{
					調査:(上杉謙信.身分)==(城主)
					調査:(上杉謙信.身分)==(国主)
					調査:(上杉謙信.身分)==(大名)
				}
			}
		}
		スクリプト:{
			ＳＥスタート:(雑踏)
			ナレーション:[[ガヤガヤ、ザワザワ]]
			会話:(剣術の師範,僧侶)[[御坊は確か、越後の生まれでしたな…\n毘沙門天の権化と名高い(上杉謙信)様、\nやはり噂通りでしょうか？]]
			会話:(僧侶,剣術の師範)[[うむ、お強い方じゃ\nその用兵はまさに神がかっておられる]]
			会話:(僧侶,剣術の師範)[[直江津の僧は公ゆかりの林泉寺の出、\n興味がおありなら一度訪ねてみては？]]
			会話:(剣術の師範,僧侶)[[ほう…\nそれは是非とも一度訪ねてみましょう]]
			ナレーション:[[直江津の僧に何度か話かけることで、\n(上杉謙信)に特殊効果を付与できます]]
		}
	}
	
	イベント:軍神導入{
		属性:何度でも｜ひかえめ
		発生契機:人物会話時(僧侶)
		発生条件:{
			調査:(状況::場面)==(寺)
		}
		スクリプト:{
		ＡＮＤ調査:{
			調査:(Ｒｎｄ１００)<(5)
			調査:(状況::拠点)==(直江津の町)
			ＯＲ調査:{
				調査:(カード::軍神.所持フラグ)==(持っている)
				ＡＮＤ調査:{
					調査:(上杉謙信.死亡フラグ)==(生存)
					ＯＲ調査:{
						調査:(上杉謙信.身分)==(城主)
						調査:(上杉謙信.身分)==(国主)
						調査:(上杉謙信.身分)==(大名)
					}
				}
			}
		}
		分岐:(1){
			ＯＲ調査:{
				調査:(イベントフラグ::毘沙門天有効)==(成立)
				調査:(イベントフラグ::軍神効果有効)==(成立)
			}
			分岐:(0){
			}
			分岐:(1){
				調査:(イベントフラグ::毘沙門天有効)==(成立)
				分岐:(0){
					ナレーション:[[(上杉謙信)の特殊効果\n「毘沙門天」は「無効」となっています]]
				}
				分岐:(1){
					ナレーション:[[(上杉謙信)の特殊効果\n「毘沙門天」は「有効」となっています]]
					調査:(イベントフラグ::毘沙門天報告)==(成立)
					分岐:(0){
						ナレーション:[[「毘沙門天」の効果発同時の報告は\n現在「なし」となっています]]
					}
					分岐:(1){
						ナレーション:[[「毘沙門天」の効果発同時の報告は\n現在「あり」となっています]]
					}
				}
				調査:(イベントフラグ::軍神効果有効)==(成立)
				分岐:(0){
					調査:(カード::軍神.所持フラグ)==(持っている)
					分岐:(1){
						ナレーション:[[(主人公.名)の特殊効果\n「軍神」は「無効」となっています]]
					}
				}
				分岐:(1){
					ナレーション:[[(主人公.名)の特殊効果\n「軍神」は「有効」となっています]]
					調査:(イベントフラグ::軍神効果報告)==(成立)
					分岐:(0){
						ナレーション:[[「軍神」の効果発同時の報告は\n現在「なし」となっています]]
					}
					分岐:(1){
						ナレーション:[[「軍神」の効果発同時の報告は\n現在「あり」となっています]]
					}
				}
			
			}
			会話:(僧侶,上杉謙信)[[(上杉謙信)様は無類の戦上手\n戦神毘沙門天の生まれかわりのようなお方]]
			調査:(上杉謙信.死亡フラグ)==(生存)
			分岐:(0){
				会話:(僧侶,主人公)[[まさに、日の本無双の名大将でいらっしゃった]]
			}
			分岐:(1){
				会話:(僧侶,主人公)[[まさに、日の本無双の名大将でいらっしゃる]]
				ナレーション:[[(上杉謙信)の直轄城において、兵の士気と訓練度が100となります]]
				ナレーション:[[また、野戦において\n(上杉謙信)が率いる軍団の武将は、\n統率力が大幅に上昇します]]
				ナレーション:[[特殊効果「毘沙門天」を有効にしますか？]]
				選択:[[はい]][[いいえ]]
				分岐:(0){
					ＳＥスタート:(成功音)
					更新:(イベントフラグ::毘沙門天有効)(成立)
					ナレーション:[[効果発動時に報告をさせますか]]
					選択:[[はい]][[いいえ]]
					分岐:(0){
						ＳＥスタート:(成功音)
						更新:(イベントフラグ::毘沙門天報告)(成立)
					}
					分岐:(1){
						ＳＥスタート:(キャンセル音)
						更新:(イベントフラグ::毘沙門天報告)(不成立)
					}
				}
				分岐:(1){
					ＳＥスタート:(キャンセル音)
					更新:(イベントフラグ::毘沙門天有効)(不成立)
					更新:(イベントフラグ::毘沙門天報告)(不成立)
				}
			}
			
			調査:(主人公)!=(上杉謙信)
			分岐:(1){
				条件ブロック:(カード::軍神.所持フラグ)==(持っている){
					会話:(僧侶,主人公)[[{二人称}も、名にしに負う常勝将軍\nまさに軍神といえましょうな]]
					ナレーション:[[(主人公.名)の城において、兵の士気と訓練度が100となります]]
					ナレーション:[[特殊効果「軍神」を有効にしますか？]]
					選択:[[はい]][[いいえ]]
					分岐:(0){
						ＳＥスタート:(成功音)
						更新:(イベントフラグ::軍神効果有効)(成立)
						ナレーション:[[効果発動時に報告をさせますか]]
						選択:[[はい]][[いいえ]]
						分岐:(0){
							ＳＥスタート:(成功音)
							更新:(イベントフラグ::軍神効果報告)(成立)
						}
						分岐:(1){
							ＳＥスタート:(キャンセル音)
							更新:(イベントフラグ::軍神効果報告)(不成立)
						}
					}
					分岐:(1){
						ＳＥスタート:(キャンセル音)
						更新:(イベントフラグ::軍神効果有効)(不成立)
						更新:(イベントフラグ::軍神効果報告)(不成立)
					}
				}
			}
		}
		}//スクリプト〆
	}

	イベント:軍神０１{
		属性:何度でも
		発生契機:一日開始処理の先頭
		発生条件:{
			ＯＲ調査:{
				調査:(イベントフラグ::毘沙門天有効)==(成立)
				調査:(イベントフラグ::軍神効果有効)==(成立)
			}
			ＯＲ調査:{//謙信・主人公が城持ち
				調査:(上杉謙信.身分)==(城主)
				調査:(上杉謙信.身分)==(国主)
				調査:(上杉謙信.身分)==(大名)
				ＡＮＤ調査:{
					調査:(カード::軍神.所持フラグ)==(持っている)
					ＯＲ調査:{
						調査:(主人公.身分)==(城主)
						調査:(主人公.身分)==(国主)
						調査:(主人公.身分)==(大名)
						調査:(主人公.身分)==(元締)
						調査:(主人公.身分)==(頭)
					}
				}
			}
		}
		スクリプト:{
			ＡＮＤ調査:{
				調査:(イベントフラグ::毘沙門天有効)==(成立)
				ＯＲ調査:{//謙信が城持ち
					調査:(上杉謙信.身分)==(城主)
					調査:(上杉謙信.身分)==(国主)
					調査:(上杉謙信.身分)==(大名)
				}
			}
			分岐:(1){
				調査:(上杉謙信.死亡フラグ)==(生存)
				分岐:(0){
					更新:(イベントフラグ::毘沙門天有効)(不成立)
					更新:(イベントフラグ::毘沙門天報告)(不成立)
				}
				分岐:(1){
					代入ｖ:(0)
					コンテナ設定:(城,城主,上杉謙信)
					条件ループ:(コンテナカウンタ)>(0){
						コンテナ選択:(城Ａ,先頭)
						コンテナ選抜:(削る,1)
						ＡＮＤ調査:{
							調査:(城Ａ.士気)==(100)
							調査:(城Ａ.訓練度)==(100)
						}
						分岐:(0){
							更新:(城Ａ.士気)(100)
							更新:(城Ａ.訓練度)(100)
							代入拠点Ａ:(城Ａ)
							代入ｖ:(1)
						}
					}
					調査:(ｖ)==(1)
					分岐:(1){
						ＯＲ調査:{//謙信が関係者
							調査:(主人公.所属当主)==(上杉謙信)
							調査:(主人公.所属上司)==(上杉謙信)
							調査:(上杉謙信.所属上司)==(主人公)
							調査:(上杉謙信.所属当主)==(主人公)
						}
						分岐:(1){
							条件ブロック:(イベントフラグ::毘沙門天報告)==(成立){
								ＢＧＭ変更:(軍団移動)
								画面効果:(フェードアウト)
								ナレーション:[[(上杉謙信.姓)家諸城]]
								スチル表示:(イベントスチル,出陣,無効,無効,フェード)
								画面効果:(フェードイン)
								会話:(上杉謙信,僧侶)[[{一人称}は毘沙門天の権化{ぞ}]]
								会話:(備大将,上杉謙信)[[われらには軍神の加護がある{ぞ}！！]]
								ＳＥスタート:(歓声)
								画面効果:(フェードアウト)
								スチル消去:(フェード)
								会話:(忍者,主人公)[[軍神・上杉謙信の軍は、訓練度・士気ともに極めて高い模様{です}]]
								ＢＧＭ変更:(デフォルト)
								画面効果:(フェードイン)
							}
						}
					}
				}
			}
			ＡＮＤ調査:{
				調査:(イベントフラグ::軍神効果有効)==(成立)
				ＯＲ調査:{//主人公が城持ち
					調査:(主人公.身分)==(城主)
					調査:(主人公.身分)==(国主)
					調査:(主人公.身分)==(大名)
				}
			}
			分岐:(0){
				ＡＮＤ調査:{
					調査:(イベントフラグ::軍神効果有効)==(成立)
					ＯＲ調査:{//主人公が砦持ち
						調査:(主人公.身分)==(元締)
						調査:(主人公.身分)==(頭)
					}
				}
				分岐:(1){
					代入拠点Ａ:(主人公.所属拠点)
					代入砦Ａ:(拠点Ａ)
					ＡＮＤ調査:{
						調査:(砦Ａ.士気)==(100)
						調査:(砦Ａ.訓練度)==(100)
					}
					分岐:(0){
						更新:(砦Ａ.士気)(100)
						更新:(砦Ａ.訓練度)(100)
						条件ブロック:(イベントフラグ::軍神効果報告)==(成立){
							ＢＧＭ変更:(軍団移動)
							画面効果:(フェードアウト)
							ナレーション:[[<拠点Ａ>]]
							スチル表示:(イベントスチル,エンディング忍者２,無効,無効,フェード)
							画面効果:(フェードイン)
							会話:(忍者,主人公)[[{二人称名前}は不敗！\nわれらには軍神の加護がある{ぞ}！！]]
							ＳＥスタート:(歓声)
							画面効果:(フェードアウト)
							スチル消去:(フェード)
							会話:(くノ一,主人公)[[{二人称名前}の軍は、訓練度・士気ともに極めて高い{です}]]
							ＢＧＭ変更:(デフォルト)
							画面効果:(フェードイン)
						}
					}
				}
			}
			分岐:(1){
				代入拠点Ａ:(主人公.所属拠点)
				代入城Ａ:(拠点Ａ)
				ＡＮＤ調査:{
					調査:(城Ａ.士気)==(100)
					調査:(城Ａ.訓練度)==(100)
				}
				分岐:(0){
					更新:(城Ａ.士気)(100)
					更新:(城Ａ.訓練度)(100)
					条件ブロック:(イベントフラグ::軍神効果報告)==(成立){
						ＢＧＭ変更:(軍団移動)
						画面効果:(フェードアウト)
						ナレーション:[[<拠点Ａ>]]
						スチル表示:(イベントスチル,出陣,無効,無効,フェード)
						画面効果:(フェードイン)
						会話:(備大将,主人公)[[{二人称名前}は常勝将軍！\nわれらには軍神の加護がある{ぞ}！！]]
						ＳＥスタート:(歓声)
						画面効果:(フェードアウト)
						スチル消去:(フェード)
						会話:(忍者,主人公)[[{二人称名前}の軍は、訓練度・士気ともに極めて高い{です}]]
						ＢＧＭ変更:(デフォルト)
						画面効果:(フェードイン)
					}
				}
			}
		}
	}

	イベント:毘沙門天野戦開始{
		属性:何度でも
		発生契機:野戦開始時(無効,無効)
		発生条件:{
//			調査:(主人公)!=(八板金兵衛)
			調査:(上杉謙信.死亡フラグ)==(生存)
			ＯＲ調査:{
				調査:(上杉謙信.身分)==(城主)
				調査:(上杉謙信.身分)==(国主)
				調査:(上杉謙信.身分)==(大名)
			}
			調査:(イベントフラグ::毘沙門天有効)==(成立)
			ＯＲ調査:{
				調査:(軍団１.軍団長)==(上杉謙信)
				調査:(軍団２.軍団長)==(上杉謙信)
			}
		}
		スクリプト:{
			調査:(軍団１.軍団長)==(上杉謙信)
			分岐:(0){
				代入軍団Ａ:(軍団２)
				代入軍団Ｂ:(軍団１)
			}
			分岐:(1){
				代入軍団Ａ:(軍団１)
				代入軍団Ｂ:(軍団２)
			}
			代入ｚ:(0)//上昇効果有りチェック
			代入ｙ:(0)//上昇後の統率力
			代入ｘ:(0)//報告処理実施フラグ
			代入ｗ:(0)//主人公が戦場にいるかチェック
			代入ｖ:(0)//敵弱体化有りチェック
			更新:(上杉謙信.病気フラグ)(健康)
			代入人物Ａ:(軍団Ａ.武将２)
			更新:(人物Ａ.病気フラグ)(健康)
			代入ａ:(人物Ａ.統率力)
//			更新:(八板金兵衛.武士勲功)(ａ)
			代入ｅ:(ａ)
//			数値保存６:(毘沙門天野戦武将２−,ｅ,ｆ)
			//数値保存 変数ｅ→フラグ （変数ｆ使用）
			//毘沙門天野戦武将２−
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−００)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０１)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０２)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０３)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０４)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０５)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０６)(ｆ)
			//数値保存　毘沙門天野戦武将２−　ここまで
			代入人物Ｂ:(軍団Ａ.武将３)
			更新:(人物Ｂ.病気フラグ)(健康)
			代入ｂ:(人物Ｂ.統率力)
//			更新:(八板金兵衛.商人勲功)(ｂ)
			代入ｅ:(ｂ)
//			数値保存６:(毘沙門天野戦武将３−,ｅ,ｆ)
			//数値保存 変数ｅ→フラグ （変数ｆ使用）
			//毘沙門天野戦武将３−
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−００)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０１)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０２)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０３)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０４)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０５)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０６)(ｆ)
			//数値保存　毘沙門天野戦武将３−　ここまで
			代入人物Ｃ:(軍団Ａ.武将４)
			更新:(人物Ｃ.病気フラグ)(健康)
			代入ｃ:(人物Ｃ.統率力)
//			更新:(八板金兵衛.海賊勲功)(ｃ)
			代入ｅ:(ｃ)
//			数値保存６:(毘沙門天野戦武将４−,ｅ,ｆ)
			//数値保存 変数ｅ→フラグ （変数ｆ使用）
			//毘沙門天野戦武将４−
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−００)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０１)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０２)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０３)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０４)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０５)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０６)(ｆ)
			//数値保存　毘沙門天野戦武将４−　ここまで
			代入人物Ｄ:(軍団Ａ.武将５)
			更新:(人物Ｄ.病気フラグ)(健康)
			代入ｄ:(人物Ｄ.統率力)
//			更新:(八板金兵衛.忍者勲功)(ｄ)
			代入ｅ:(ｄ)
//			数値保存６:(毘沙門天野戦武将５−,ｅ,ｆ)
			//数値保存 変数ｅ→フラグ （変数ｆ使用）
			//毘沙門天野戦武将５−
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−００)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０１)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０２)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０３)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０４)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０５)(ｆ)
			代入ｅ:(ｅ)/(2)
			代入ｆ:(ｅ)%(2)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０６)(ｆ)
			//数値保存　毘沙門天野戦武将５−　ここまで
			代入ｙ:(88)
			条件ブロック:(ａ)<(ｙ){
				調査:(人物Ａ)!=(備大将)
				分岐:(1){
					更新:(人物Ａ.統率力)(ｙ)
					代入ｚ:(1)
					更新:(イベントフラグ::毘沙門天野戦)(成立)
				}
			}
			条件ブロック:(ｂ)<(ｙ){
				調査:(人物Ｂ)!=(備大将)
				分岐:(1){
					更新:(人物Ｂ.統率力)(ｙ)
					代入ｚ:(1)
					更新:(イベントフラグ::毘沙門天野戦)(成立)
				}
			}
			条件ブロック:(ｃ)<(ｙ){
				調査:(人物Ｃ)!=(備大将)
				分岐:(1){
					更新:(人物Ｃ.統率力)(ｙ)
					代入ｚ:(1)
					更新:(イベントフラグ::毘沙門天野戦)(成立)
				}
			}
			条件ブロック:(ｄ)<(ｙ){
				調査:(人物Ｄ)!=(備大将)
				分岐:(1){
					更新:(人物Ｄ.統率力)(ｙ)
					代入ｚ:(1)
					更新:(イベントフラグ::毘沙門天野戦)(成立)
				}
			}
			ＯＲ調査:{//主人公が合戦場にいるか？
				調査:(軍団Ａ.軍団長)==(主人公)
				調査:(軍団Ｂ.軍団長)==(主人公)
				調査:(軍団Ａ.武将２)==(主人公)
				調査:(軍団Ｂ.武将２)==(主人公)
				調査:(軍団Ａ.武将３)==(主人公)
				調査:(軍団Ｂ.武将３)==(主人公)
				調査:(軍団Ａ.武将４)==(主人公)
				調査:(軍団Ｂ.武将４)==(主人公)
				調査:(軍団Ａ.武将５)==(主人公)
				調査:(軍団Ｂ.武将５)==(主人公)
			}
			分岐:(1){
				代入ｗ:(1)
			}
			//敵軍団弱体化処理
			代入人物Ｅ:(軍団Ｂ.軍団長)
			ＯＲ調査:{
				調査:(人物Ｅ)==(武田信玄)
				調査:(人物Ｅ)==(北条氏康)
			}
			分岐:(0){//敵軍団武将を全員病気に
				更新:(人物Ｅ.病気フラグ)(病気)
				代入人物Ａ:(軍団Ｂ.武将２)
				更新:(人物Ａ.病気フラグ)(病気)
				代入人物Ｂ:(軍団Ｂ.武将３)
				更新:(人物Ｂ.病気フラグ)(病気)
				代入人物Ｃ:(軍団Ｂ.武将４)
				更新:(人物Ｃ.病気フラグ)(病気)
				代入人物Ｄ:(軍団Ｂ.武将５)
				更新:(人物Ｄ.病気フラグ)(病気)
				更新:(イベントフラグ::毘沙門天野戦)(成立)
				代入ｖ:(1)
			}
			//敵軍団弱体化処理終了
			
			ＯＲ調査:{
				調査:(ｚ)==(1)
				調査:(ｖ)==(1)
			}
			分岐:(1){
				代入人物Ｅ:(軍団Ｂ.軍団長)
				代入拠点Ｂ:(人物Ｅ.所属拠点)
				調査:(ｗ)==(1)
				分岐:(0){//主人公が合戦場にいない
					条件ブロック:(イベントフラグ::毘沙門天報告)==(成立){
						代入ｘ:(1)
						ＳＥスタート:(忍者報告)
						会話:(忍者,主人公)[[(上杉謙信)が<拠点Ｂ>の(人物Ｅ)と野戦に入りました]]
					}
				}
				分岐:(1){//主人公が合戦場いる
					代入ｘ:(1)
				}
				調査:(ｘ)==(1)
				分岐:(1){
					ＢＧＭ変更:(軍団移動)
					画面効果:(フェードアウト)
					条件ブロック:(ｚ)==(1){
						ナレーション:[[(上杉謙信.姓)軍陣中]]
						スチル表示:(イベントスチル,小山評定,無効,無効,フェード)
						画面効果:(フェードイン)
						会話:(上杉謙信,備大将)[[こたびの義戦、天も照覧あれ！]]
						会話:(備大将,上杉謙信)[[{おお}！！]]
						ＳＥスタート:(歓声)
						画面効果:(フェードアウト)
						スチル消去:(フェード)
						ＳＥスタート:(バー上昇)
						ナレーション:[[(上杉謙信)軍の武将の統率力が一時的に上昇しました]]
					}
					調査:(ｖ)==(1)
					分岐:(0){//上杉謙信の相手が武田信玄など
						ナレーション:[[(人物Ｅ.姓)軍陣中]]
						スチル表示:(イベントスチル,空城の計,無効,無効,フェード)
						画面効果:(フェードイン)
						会話:(忍者,人物Ｅ)[[(上杉謙信.姓)軍、その士気は天をつくほどです]]
						会話:(人物Ｅ,備大将)[[さすがは、軍神というところ{だ}{な}]]
						代入人物Ａ:(軍団Ｂ.武将２)
						代入人物Ｂ:(軍団Ｂ.武将３)
						ＳＥスタート:(歓声)
						調査:(人物Ｅ)==(武田信玄)
						分岐:(0){
							会話:(備大将,人物Ｅ)[[（ごく）\n相手はあの軍神率いる戦国最強軍…]]
							会話:(人物Ａ,人物Ｅ)[[なんの、{二人称}とて\n無双の名大将{ではない}か\n{上杉謙信.名前}とて畏るるに足り{ません}{ぞ}]]
						}
						分岐:(1){
							会話:(人物Ａ,人物Ｅ)[[なんの、御屋形様とて\n甲斐の虎と謳われた無双の名大将\n(上杉謙信)とて畏るるに足り{ません}{ぞ}]]
							会話:(人物Ｂ,人物Ｅ)[[四如の旗の下、(上杉謙信.姓)勢を蹴散らしてご覧にいれましょう{ぞ}]]
						}
						会話:(備大将,人物Ａ)[[{おお}！！]]
						画面効果:(フェードアウト)
						スチル消去:(フェード)
					}
					分岐:(1){
						ナレーション:[[(人物Ｅ.姓)軍陣中]]
						スチル表示:(イベントスチル,空城の計,無効,無効,フェード)
						画面効果:(フェードイン)
						会話:(忍者,人物Ｅ)[[(上杉謙信.姓)軍、その士気は天をつくほどです]]
						会話:(人物Ｅ,備大将)[[さすがは、越後の龍…]]
						会話:(備大将,人物Ｅ)[[（ごく）\n相手はあの軍神率いる戦国最強軍…]]
						ＳＥスタート:(混乱)
						会話:(人物Ｅ,備大将)[[（将兵らが畏縮しているよう{だ}{な}）]]
						画面効果:(フェードアウト)
						スチル消去:(フェード)
						ＳＥスタート:(バー減少)
						ナレーション:[[(人物Ｅ)軍の武将の能力が一時的に下降しました]]
					}
					ＢＧＭ変更:(デフォルト)
					画面効果:(フェードイン)
				}
			}
		}
	}
	イベント:毘沙門天野戦終了{
		属性:何度でも
		発生契機:野戦終了時(無効,無効,無効)
		発生条件:{
			調査:(イベントフラグ::毘沙門天野戦)==(成立)
			ＯＲ調査:{
				調査:(軍団１.軍団長)==(上杉謙信)
				調査:(軍団２.軍団長)==(上杉謙信)
			}
		}
		スクリプト:{
			調査:(軍団１.軍団長)==(上杉謙信)
			分岐:(0){
				代入軍団Ａ:(軍団２)
				代入軍団Ｂ:(軍団１)
			}
			分岐:(1){
				代入軍団Ａ:(軍団１)
				代入軍団Ｂ:(軍団２)
			}
			代入ｚ:(0)
			代入人物Ａ:(軍団Ａ.武将２)
			更新:(人物Ａ.病気フラグ)(健康)
//			代入ａ:(八板金兵衛.武士勲功)
//			数値読出６:(毘沙門天野戦武将２−,ａ,ｆ)
			//数値読出 フラグ→変数ａ （変数ｆ使用）
			//毘沙門天野戦武将２−
			代入ａ:(Ｚｅｒｏ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−００)*(1)
			代入ａ:(ａ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０１)*(2)
			代入ａ:(ａ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０２)*(4)
			代入ａ:(ａ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０３)*(8)
			代入ａ:(ａ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０４)*(16)
			代入ａ:(ａ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０５)*(32)
			代入ａ:(ａ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０６)*(64)
			代入ａ:(ａ)+(ｆ)
			//数値読出　毘沙門天野戦武将２−　ここまで
			更新:(人物Ａ.統率力)(ａ)
//			更新:(八板金兵衛.武士勲功)(0)
			
			代入人物Ｂ:(軍団Ａ.武将３)
			更新:(人物Ｂ.病気フラグ)(健康)
//			代入ｂ:(八板金兵衛.商人勲功)
//			数値読出６:(毘沙門天野戦武将３−,ｂ,ｆ)
			//数値読出 フラグ→変数ｂ （変数ｆ使用）
			//毘沙門天野戦武将３−
			代入ｂ:(Ｚｅｒｏ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−００)*(1)
			代入ｂ:(ｂ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０１)*(2)
			代入ｂ:(ｂ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０２)*(4)
			代入ｂ:(ｂ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０３)*(8)
			代入ｂ:(ｂ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０４)*(16)
			代入ｂ:(ｂ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０５)*(32)
			代入ｂ:(ｂ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０６)*(64)
			代入ｂ:(ｂ)+(ｆ)
			//数値読出　毘沙門天野戦武将３−　ここまで
			更新:(人物Ｂ.統率力)(ｂ)
//			更新:(八板金兵衛.商人勲功)(0)
			
			代入人物Ｃ:(軍団Ａ.武将４)
			更新:(人物Ｃ.病気フラグ)(健康)
//			代入ｃ:(八板金兵衛.海賊勲功)
//			数値読出６:(毘沙門天野戦武将４−,ｃ,ｆ)
			//数値読出 フラグ→変数ｃ （変数ｆ使用）
			//毘沙門天野戦武将４−
			代入ｃ:(Ｚｅｒｏ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−００)*(1)
			代入ｃ:(ｃ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０１)*(2)
			代入ｃ:(ｃ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０２)*(4)
			代入ｃ:(ｃ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０３)*(8)
			代入ｃ:(ｃ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０４)*(16)
			代入ｃ:(ｃ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０５)*(32)
			代入ｃ:(ｃ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０６)*(64)
			代入ｃ:(ｃ)+(ｆ)
			//数値読出　毘沙門天野戦武将４−　ここまで
			更新:(人物Ｃ.統率力)(ｃ)
//			更新:(八板金兵衛.海賊勲功)(0)
			
			代入人物Ｄ:(軍団Ａ.武将５)
			更新:(人物Ｄ.病気フラグ)(健康)
//			代入ｄ:(八板金兵衛.忍者勲功)
//			数値読出６:(毘沙門天野戦武将５−,ｄ,ｆ)
			//数値読出 フラグ→変数ｄ （変数ｆ使用）
			//毘沙門天野戦武将５−
			代入ｄ:(Ｚｅｒｏ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−００)*(1)
			代入ｄ:(ｄ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０１)*(2)
			代入ｄ:(ｄ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０２)*(4)
			代入ｄ:(ｄ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０３)*(8)
			代入ｄ:(ｄ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０４)*(16)
			代入ｄ:(ｄ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０５)*(32)
			代入ｄ:(ｄ)+(ｆ)
			代入ｆ:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０６)*(64)
			代入ｄ:(ｄ)+(ｆ)
			//数値読出　毘沙門天野戦武将５−　ここまで
			更新:(人物Ｄ.統率力)(ｄ)
//			更新:(八板金兵衛.忍者勲功)(0)
			
//数値保持フラグの初期化
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−００)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０１)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０２)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０３)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０４)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０５)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−０６)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将２−００)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０１)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０２)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０３)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０４)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０５)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将３−０６)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−００)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０１)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０２)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０３)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０４)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０５)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将４−０６)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−００)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０１)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０２)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０３)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０４)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０５)(0)
			更新:(イベントフラグ::数値保持フラグ−毘沙門天野戦武将５−０６)(0)
//初期化ここまで			
			
			//敵軍団の病気治療
			代入人物Ａ:(軍団Ｂ.武将２)
			更新:(人物Ａ.病気フラグ)(健康)
			代入人物Ｂ:(軍団Ｂ.武将３)
			更新:(人物Ｂ.病気フラグ)(健康)
			代入人物Ｃ:(軍団Ｂ.武将４)
			更新:(人物Ｃ.病気フラグ)(健康)
			代入人物Ｄ:(軍団Ｂ.武将５)
			更新:(人物Ｄ.病気フラグ)(健康)
			代入人物Ｅ:(軍団Ｂ.軍団長)
			更新:(人物Ｅ.病気フラグ)(健康)
			
			更新:(イベントフラグ::毘沙門天野戦)(不成立)
		}
	}
}