太閤立志伝５イベントソース

チャプター:{

//信玄上洛

イベント:甲相駿三国同盟の崩壊{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(人物::主人公)!=(武田信玄)
		調査:(人物::主人公)!=(北条氏康)
		調査:(人物::主人公)!=(上杉謙信)
		調査:(大名家::武田信玄.存在)==(真)
		調査:(大名家::北条氏康.存在)==(真)
		調査:(大名家::今川氏真.存在)==(真)
		調査:(大名家::徳川家康.存在)==(真)
		調査:(大名家::武田信玄.外交同盟(今川氏真))==(同盟なし)
		調査:(大名家::武田信玄.外交同盟(徳川家康))==(同盟)
		調査:(大名家::武田信玄.外交同盟(北条氏康))==(同盟)
	}
	スクリプト:{
		更新:(大名家::武田信玄.外交同盟(北条氏康))(同盟なし)
		更新:(大名家::武田信玄.外交感情(北条氏康))(絶交)
		調査:(大名家::上杉謙信.外交同盟(北条氏康))==(同盟なし)
		分岐:(真){
			更新:(大名家::上杉謙信.外交同盟(北条氏康))(同盟)
			更新:(大名家::上杉謙信.外交感情(北条氏康))(盟友)
		}
	}
}

イベント:今川家の衰退{
	属性:何度でも
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(人物::今川義元.死亡フラグ)==(死亡)
		調査:(大名家::武田信玄.存在)==(真)
		調査:(大名家::今川氏真.存在)==(真)
		調査:(大名家::徳川家康.存在)==(真)
		調査:(大名家::足利義昭.存在)==(真)
		調査:(大名家::武田信玄.外交同盟(今川氏真))==(同盟なし)
		調査:(人物::主人公.所属大名家)!=(大名家::今川氏真)
	}
	スクリプト:{
		コンテナ設定:(城,所属大名家,今川氏真)
		ループ:{
			調査:(コンテナカウンタ)>(0)
			ブロック脱出:(偽)
			コンテナ選択:(城Ａ,先頭)
			更新:(城::城Ａ.兵士数)(1000)
			更新:(城::城Ａ.防御度)(10)
			コンテナ選抜:(削る,1)
		}
	}
}

//瓶割り柴田

イベント:六角承禎隠居{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(Ｒｎｄ１００)<(10)
		調査:(状況::年)>=(1559)
		調査:(大名家::六角承禎.存在)==(真)
		調査:(人物::六角義治.所属大名家)==(六角承禎)
		調査:(人物::主人公)!=(六角承禎)
		調査:(人物::主人公)!=(六角義治)
		調査:(人物::主人公.所属大名家)!=(六角承禎)
		調査:(人物::六角承禎.イベント参加可能)==(真)
		調査:(人物::六角義治.イベント参加可能)==(真)
	}
	スクリプト:{
		ＳＥスタート:(忍者報告)
		会話:(忍者,主人公)[[(主人公)さま\n(六角承禎.姓)家当主の(六角承禎)さまが\n隠居なさいました]]
		会話:(忍者,主人公)[[(六角義治)さまが\n家督を継いだようでございます]]
		家督を譲る:(六角承禎,六角義治)
		調査:(人物::柴田勝家.所属大名家)==(織田信長)
		分岐:(真){
			更新:(人物::六角承禎.仕官傾向)(その気なし)
		}
	}
}

//謙信上洛

イベント:上野国所属変更{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(人物::主人公)!=(北条氏康)
		調査:(人物::主人公)!=(上杉謙信)
		調査:(大名家::北条氏康.存在)==(真)
		調査:(大名家::上杉謙信.存在)==(真)
		調査:(大名家::北条氏康.外交同盟(上杉謙信))==(同盟)
	}
	スクリプト:{
		ＡＮＤ調査:{
			調査:(城::厩橋.所属大名家)==(北条氏康)
			調査:(人物::主人公.所属拠点)!=(厩橋城)
		}
		分岐:(真){
			城主解任:(厩橋)
			更新:(城::厩橋.城主)(上杉謙信)
		}
		ＡＮＤ調査:{
			調査:(城::沼田.所属大名家)==(北条氏康)
			調査:(人物::主人公.所属拠点)!=(沼田城)
		}
		分岐:(真){
			城主解任:(沼田)
			更新:(城::沼田.城主)(上杉謙信)
		}
		ＡＮＤ調査:{
			調査:(城::館林.所属大名家)==(北条氏康)
			調査:(人物::主人公.所属拠点)!=(館林城)
		}
		分岐:(真){
			城主解任:(館林)
			更新:(城::館林.城主)(上杉謙信)
		}
	}
}

イベント:上杉景勝出現{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(状況::年)>=(1560)
		調査:(人物::主人公)!=(上杉景勝)
		調査:(人物::主人公)!=(上杉謙信)
		調査:(人物::上杉景勝.死亡フラグ)==(生存)
		調査:(人物::上杉景勝.出現フラグ)==(未出現)
		調査:(大名家::上杉謙信.存在)==(真)
		調査:(大名家::武田信玄.存在)==(真)
		調査:(人物::今川義元.死亡フラグ)==(死亡)
		調査:(大名家::今川氏真.存在)==(偽)
	}
	スクリプト:{
		人物解雇:(上杉景勝,京の町,出現済み)
		更新:(人物::上杉景勝.武士勲功)(1400)
		人物登用:(上杉景勝,直臣,上杉謙信)
	}
}

//長篠の戦い

イベント:長篠城主任命{
	属性:何度でも
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(大名家::織田信長.存在)==(真)
		調査:(大名家::徳川家康.存在)==(真)
		調査:(大名家::武田勝頼.存在)==(真)
		調査:(人物::主人公)!=(徳川家康)
		調査:(人物::主人公)!=(奥平信昌)
		調査:(人物::奥平信昌.所属上司)!=(主人公)
		調査:(人物::主人公.所属上司)!=(奥平信昌)
		調査:(人物::奥平信昌.所属大名家)==(徳川家康)
		調査:(人物::奥平信昌.イベント参加可能)==(真)
		調査:(人物::主人公)!=(鳥居強右衛門)
		調査:(人物::鳥居強右衛門.所属上司)!=(主人公)
		調査:(人物::鳥居強右衛門.所属大名家)==(徳川家康)
		調査:(人物::鳥居強右衛門.イベント参加可能)==(真)
		調査:(城::長篠.所属大名家)==(徳川家康)
		調査:(城::長篠.城主)!=(奥平信昌)
		調査:(人物::主人公.所属拠点)!=(長篠城)
		調査:(城::長篠.戦闘フラグ)==(平常)
	}
	スクリプト:{
		調査:(人物::奥平信昌.立場)!=(直臣)
		分岐:(真){
			人物解雇:(奥平信昌,京の町,出現済み)
			人物登用:(奥平信昌,直臣,徳川家康)
		}
		城主解任:(長篠)
		城主任命:(奥平信昌,長篠)
		調査:(人物::鳥居強右衛門.所属上司)!=(奥平信昌)
		分岐:(真){
			代入ａ:(人物::鳥居強右衛門.武士勲功)
			人物解雇:(鳥居強右衛門,京の町,出現済み)
			更新:(人物::鳥居強右衛門.武士勲功)(ａ)
			人物登用:(鳥居強右衛門,陪臣,奥平信昌)
			更新:(人物::鳥居強右衛門.武士勲功)(ａ)
		}
	}
}

//信康切腹

イベント:岡崎城主任命{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(大名家::徳川家康.存在)==(真)
		調査:(大名家::織田信長.存在)==(真)
		調査:(大名家::徳川家康.外交同盟(織田信長))!=(同盟なし)
		調査:(大名家::武田勝頼.存在)==(真)
		調査:(人物::主人公)!=(徳川信康)
		調査:(人物::主人公)!=(徳川家康)
		調査:(人物::徳川信康.所属大名家)==(徳川家康)
		調査:(人物::徳川信康.所属上司)!=(主人公)
		調査:(人物::主人公.所属上司)!=(人物::徳川信康)
		調査:(人物::徳川信康.イベント参加可能)==(真)
		調査:(城::岡崎.所属大名家)==(徳川家康)
		調査:(城::岡崎.城主)!=(徳川信康)
		調査:(人物::主人公.所属拠点)!=(岡崎城)
		調査:(城::岡崎.戦闘フラグ)==(平常)
	}
	スクリプト:{
		調査:(人物::徳川信康.立場)!=(直臣)
		分岐:(真){
			人物解雇:(徳川信康,京の町,出現済み)
			人物登用:(徳川信康,直臣,徳川家康)
		}
		城主解任:(岡崎)
		城主任命:(徳川信康,岡崎)
	}
}

//木津川口の戦い

イベント:河野家従属{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(Ｒｎｄ１００)<(10)
		調査:(状況::年)<=(1581)
		調査:(人物::主人公)!=(河野通宣)
		調査:(人物::主人公)!=(毛利元就)
		調査:(大名家::河野通宣.存在)==(真)
		調査:(大名家::毛利元就.存在)==(真)
		調査:(大名家::河野通宣.隣接大名家(毛利元就))==(真)
		代入ａ:(大名家::毛利元就.支配力)/(3)
		代入ｂ:(大名家::河野通宣.支配力)
		調査:(ａ)>(ｂ)
		調査:(大名家::河野通宣.外交同盟(毛利元就))==(同盟なし)
	}
	スクリプト:{
		ＳＥスタート:(忍者報告)
		調査:(主人公.所属大名家)==(河野通宣)
		分岐:(真){
			会話:(忍者,主人公)[[当家は(毛利元就.姓)家に従属しました]]
		}
		分岐:(偽){
			調査:(主人公.所属大名家)==(毛利元就)
			分岐:(真){
				会話:(忍者,主人公)[[(河野通宣.姓)家が当家に従属しました]]
			}
			分岐:(偽){
				会話:(忍者,主人公)[[(河野通宣.姓)家が(毛利元就.姓)家に従属しました]]
			}
		}
		更新:(大名家::毛利元就.外交同盟(河野通宣))(支配)
		更新:(大名家::毛利元就.外交感情(河野通宣))(盟友)
		ＡＮＤ調査:{
			調査:(海賊衆::村上水軍.存在)==(真)
			調査:(人物::主人公.所属海賊衆)!=(村上水軍)
			調査:(海賊衆::村上水軍.支持大名家)==(河野通宣)
		}
		分岐:(真){
			更新:(海賊衆::村上水軍.外交同盟(河野通宣))(同盟なし)
			更新:(大名家::毛利元就.外交同盟(村上水軍))(支配)
		}
	}
}

イベント:毛利本願寺同盟{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(Ｒｎｄ１００)<(30)
		調査:(人物::主人公)!=(本願寺顕如)
		調査:(人物::主人公)!=(毛利輝元)
		調査:(大名家::本願寺顕如.存在)==(真)
		調査:(大名家::本願寺顕如.本城)==(石山本願)
		調査:(大名家::毛利輝元.存在)==(真)
		調査:(大名家::本願寺顕如.外交同盟(毛利輝元))==(同盟なし)
		調査:(大名家::織田信長.存在)==(真)
		調査:(大名家::足利義昭.存在)==(偽)
		調査:(人物::足利義昭.所属勢力タイプ)==(浪人)
	}
	スクリプト:{
		ＳＥスタート:(忍者報告)
		調査:(主人公.所属大名家)==(毛利輝元)
		分岐:(真){
			会話:(忍者,主人公)[[当家は本願寺と同盟を結びました]]
		}
		分岐:(偽){
			調査:(主人公.所属大名家)==(本願寺顕如)
			分岐:(真){
				会話:(忍者,主人公)[[当家は(毛利輝元.姓)家と同盟を結びました]]
			}
			分岐:(偽){
				会話:(忍者,主人公)[[(毛利輝元.姓)家と本願寺が同盟を結びました]]
			}
		}
		更新:(大名家::毛利輝元.外交同盟(本願寺顕如))(同盟)
		調査:(大名家::毛利輝元.外交感情(本願寺顕如))<(友好)
		分岐:(真){
			更新:(大名家::毛利輝元.外交感情(本願寺顕如))(友好)
		}
	}
}

//荒木村重造反

イベント:荒木村重寝返り{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(Ｒｎｄ１００)<(10)
		調査:(大名家::織田信長.存在)==(真)
		ＯＲ調査:{
			代入人物Ａ:(人物::三好長慶)
			代入大名家Ａ:(大名家::三好長慶)
			調査:(大名家::三好長慶.存在)==(真)
			代入人物Ａ:(人物::三好義継)
			代入大名家Ａ:(大名家::三好義継)
			調査:(大名家::三好義継.存在)==(真)
		}
		ＯＲ調査:{
			調査:(城::二条.所属大名家)==(織田信長)
			調査:(城::二条.所属大名家)==(足利義昭)
		}
		調査:(人物::主人公)!=(人物Ａ)
		調査:(大名家::大名家Ａ.隣接大名家(織田信長))==(真)
		調査:(人物::主人公)!=(荒木村重)
		調査:(人物::主人公.所属上司)!=(荒木村重)
		調査:(人物::荒木村重.所属大名家)==(大名家Ａ)
		調査:(人物::荒木村重.イベント参加可能)==(真)
		調査:(人物::荒木村重.身分)==(城主)
		調査:(人物::荒木村重.所属拠点)==(有岡城)
	}
	スクリプト:{
		ＳＥスタート:(忍者報告)
		調査:(主人公.所属大名家)==(大名家Ａ)
		分岐:(真){
			会話:(忍者,主人公)[[(主人公)さま、有岡城城主の\n(荒木村重)が当家を裏切って\n(織田信長.姓)家に寝返りました！]]
		}
		分岐:(偽){
			調査:(主人公.所属大名家)==(織田信長)
			分岐:(真){
				会話:(忍者,主人公)[[(主人公)さま、有岡城城主の\n(荒木村重)が<大名家Ａ>を裏切って\n当家に寝返りました！]]
			}
			分岐:(偽){
				会話:(忍者,主人公)[[(主人公)さま、有岡城城主の\n(荒木村重)が<大名家Ａ>を裏切って\n(織田信長.姓)家に寝返りました！]]
			}
		}
		コンテナ設定:(人物,所属上司,荒木村重)
		コンテナ絞り込み:(人物,立場,寄騎)
		ループ:{
			調査:(コンテナカウンタ)>(0)
			ブロック脱出:(偽)
			コンテナ選択:(人物Ｂ,先頭)
			代入ａ:(人物::人物Ｂ.武士勲功)
			人物解雇:(人物Ｂ,京の町,出現済み)
			更新:(人物::人物Ｂ.武士勲功)(ａ)
			人物登用:(人物Ｂ,直臣,人物Ａ)
			更新:(人物::人物Ｂ.武士勲功)(ａ)
			コンテナ選抜:(削る,1)
		}//ループ〆
		人物登用:(荒木村重,直臣,織田信長)
	}
}

//別所長治造反

イベント:別所長治登場{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(状況::年)>=(1563)
		調査:(人物::主人公)!=(別所長治)
		調査:(人物::主人公)!=(赤松義祐)
		調査:(人物::別所長治.死亡フラグ)==(生存)
		調査:(人物::別所長治.出現フラグ)==(未出現)
		調査:(大名家::赤松義祐.存在)==(真)
		調査:(人物::赤松義祐.イベント参加可能)==(真)
		調査:(城::三木.所属大名家)==(赤松義祐)
		調査:(人物::主人公.所属拠点)!=(三木城)
		調査:(城::三木.戦闘フラグ)==(平常)
	}
	スクリプト:{
		人物解雇:(別所長治,京の町,出現済み)
		人物登用:(別所長治,直臣,赤松義祐)
		城主解任:(三木)
		城主任命:(別所長治,三木)
	}
}

イベント:三木城主任命{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(状況::年)>=(1563)
		調査:(大名家::織田信長.存在)==(真)
		調査:(人物::主人公)!=(別所長治)
		調査:(人物::主人公)!=(織田信長)
		調査:(人物::別所長治.所属大名家)==(織田信長)
		調査:(人物::別所長治.所属上司)!=(主人公)
		調査:(人物::主人公.所属上司)!=(別所長治)
		調査:(人物::別所長治.イベント参加可能)==(真)
		調査:(城::三木.所属大名家)==(織田信長)
		調査:(城::三木.城主)!=(別所長治)
		調査:(人物::主人公.所属拠点)!=(三木城)
		調査:(城::三木.戦闘フラグ)==(平常)
	}
	スクリプト:{
		調査:(人物::別所長治.立場)!=(直臣)
		分岐:(真){
			人物解雇:(別所長治,京の町,出現済み)
			人物登用:(別所長治,直臣,織田信長)
		}
		城主解任:(三木)
		城主任命:(別所長治,三木)
	}
}

//本能寺の変

イベント:宇喜多家従属{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(人物::主人公)!=(宇喜多直家)
		調査:(人物::主人公)!=(織田信長)
		調査:(大名家::宇喜多直家.存在)==(真)
		調査:(大名家::織田信長.存在)==(真)
		調査:(人物::豊臣秀吉.所属大名家)==(織田信長)
		調査:(城::御着.城主)==(豊臣秀吉)
		調査:(大名家::宇喜多直家.隣接大名家(織田信長))==(真)
		調査:(大名家::宇喜多直家.外交同盟(織田信長))==(同盟なし)
	}
	スクリプト:{
		ＳＥスタート:(忍者報告)
		調査:(主人公.所属大名家)==(織田信長)
		分岐:(真){
			会話:(忍者,主人公)[[(宇喜多直家.姓)家が当家に従属しました]]
		}
		分岐:(偽){
			調査:(主人公.所属大名家)==(宇喜多直家)
			分岐:(真){
				会話:(忍者,主人公)[[当家は(織田信長.姓)家に従属しました]]
			}
			分岐:(偽){
				会話:(忍者,主人公)[[(宇喜多直家.姓)家が(織田信長.姓)家に従属しました]]
			}
		}
		更新:(大名家::織田信長.外交同盟(宇喜多直家))(支配)
		調査:(大名家::織田信長.外交感情(宇喜多直家))<(友好)
		分岐:(真){
			更新:(大名家::織田信長.外交感情(宇喜多直家))(友好)
		}
	}
}

イベント:本能寺発生補助{
	属性:何度でも
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(大名家::織田信長.存在)==(真)
		調査:(大名家::徳川家康.存在)==(真)
		調査:(人物::主人公)!=(織田信長)
		調査:(国::尾張.全城制圧(織田信長))==(真)
		調査:(国::美濃.全城制圧(織田信長))==(真)
		調査:(国::南近江.全城制圧(織田信長))==(真)
		調査:(国::北近江.全城制圧(織田信長))==(真)
		調査:(国::越前.全城制圧(織田信長))==(真)
		調査:(国::山城.全城制圧(織田信長))==(真)
		調査:(国::摂津.全城制圧(織田信長))==(真)
		調査:(国::丹波.全城制圧(織田信長))==(真)
		調査:(国::播磨.全城制圧(織田信長))==(真)
	}
	スクリプト:{
		調査:(人物::織田信長.所属拠点)!=(観音寺城)
		分岐:(真){
			城主解任:(観音寺)
			居城変更:(織田信長,観音寺)
		}
		ＡＮＤ調査:{
			調査:(人物::豊臣秀吉.イベント参加可能)==(真)
			調査:(人物::豊臣秀吉.所属大名家)==(織田信長)
			調査:(人物::豊臣秀吉.身分)!=(城主)
			調査:(人物::主人公)!=(豊臣秀吉)
			調査:(人物::主人公.所属上司)!=(豊臣秀吉)
		}
		分岐:(真){
			ＡＮＤ調査:{
				調査:(人物::豊臣秀吉.所属拠点)!=(御着城)
				調査:(人物::主人公.所属拠点)!=(御着城)
			}
			分岐:(真){
				城主解任:(御着)
				国主任命:(豊臣秀吉,播磨,御着)
			}
			ＡＮＤ調査:{
				調査:(城::今浜.城主)!=(豊臣秀吉)
				調査:(人物::主人公.所属拠点)!=(今浜城)
			}
			分岐:(真){
				城主解任:(今浜)
				更新:(城::今浜.城主)(豊臣秀吉)
			}
		}
		ＡＮＤ調査:{
			調査:(人物::明智光秀.所属拠点)!=(丹波亀山城)
			調査:(人物::主人公.所属拠点)!=(丹波亀山城)
			調査:(人物::明智光秀.イベント参加可能)==(真)
			調査:(人物::明智光秀.所属大名家)==(織田信長)
			調査:(人物::主人公)!=(明智光秀)
			調査:(人物::主人公.所属上司)!=(明智光秀)
		}
		分岐:(真){
			城主解任:(丹波亀山)
			国主任命:(明智光秀,丹波,丹波亀山)
		}
		ＡＮＤ調査:{
			調査:(人物::柴田勝家.イベント参加可能)==(真)
			調査:(人物::柴田勝家.所属大名家)==(織田信長)
			調査:(人物::主人公)!=(柴田勝家)
			調査:(人物::主人公.所属上司)!=(柴田勝家)
		}
		分岐:(真){
			ＡＮＤ調査:{
				調査:(人物::柴田勝家.所属拠点)!=(北ノ庄城)
				調査:(人物::主人公.所属拠点)!=(北ノ庄城)
			}
			分岐:(真){
				城主解任:(北ノ庄)
				国主任命:(柴田勝家,越前,北ノ庄)
			}
			ＡＮＤ調査:{
				調査:(城::金ヶ崎.城主)!=(柴田勝家)
				調査:(人物::主人公.所属拠点)!=(金ヶ崎城)
			}
			分岐:(真){
				城主解任:(金ヶ崎)
				更新:(城::金ヶ崎.城主)(柴田勝家)
			}
		}
		ＡＮＤ調査:{
			調査:(人物::織田信忠.イベント参加可能)==(真)
			調査:(人物::織田信忠.所属大名家)==(織田信長)
			調査:(人物::主人公)!=(織田信忠)
			調査:(人物::主人公.所属上司)!=(織田信忠)
			調査:(人物::織田信忠.所属上司)!=(主人公)
			調査:(人物::織田信忠.立場)!=(直臣)
		}
		分岐:(真){
			人物解雇:(織田信忠,京の町,出現済み)
			人物登用:(織田信忠,直臣,織田信長)
		}
		ＡＮＤ調査:{
			調査:(人物::織田信雄.イベント参加可能)==(真)
			調査:(人物::織田信雄.所属大名家)==(織田信長)
			調査:(人物::主人公)!=(織田信雄)
			調査:(人物::主人公.所属上司)!=(織田信雄)
			調査:(人物::織田信雄.所属上司)!=(主人公)
			調査:(人物::織田信雄.立場)!=(直臣)
		}
		分岐:(真){
			人物解雇:(織田信雄,京の町,出現済み)
			人物登用:(織田信雄,直臣,織田信長)
		}
		ＡＮＤ調査:{
			調査:(人物::織田信孝.イベント参加可能)==(真)
			調査:(人物::織田信孝.所属大名家)==(織田信長)
			調査:(人物::主人公)!=(織田信孝)
			調査:(人物::主人公.所属上司)!=(織田信孝)
			調査:(人物::織田信孝.所属上司)!=(主人公)
			調査:(人物::織田信孝.立場)!=(直臣)
		}
		分岐:(真){
			人物解雇:(織田信孝,京の町,出現済み)
			人物登用:(織田信孝,直臣,織田信長)
		}
		ＯＲ調査:{
			調査:(城::清洲.城主)==(織田信長)
			調査:(城::清洲.城主)==(織田信忠)
			調査:(城::清洲.城主)==(織田信雄)
			調査:(城::清洲.城主)==(織田信孝)
		}
		分岐:(偽){
			城主解任:(清洲)
			更新:(城::清洲.城主)(織田信長)
		}
	}
}

//賤ヶ岳の合戦

イベント:佐久間盛政登用{
	属性:一度だけ
	発生契機:毎月処理の最後絶対
	発生条件:{
		調査:(イベントフラグ::史実イベント発生補助ＯＮ)==(成立)
		調査:(人物::主人公)!=(佐久間盛政)
		調査:(人物::主人公)!=(柴田勝家)
		調査:(人物::主人公)!=(織田信長)
		調査:(人物::柴田勝家.所属大名家)==(織田信長)
		調査:(人物::柴田勝家.身分)>=(城主)
		調査:(人物::柴田勝家.イベント参加可能)==(真)
		調査:(人物::佐久間盛政.所属大名家)==(織田信長)
		調査:(人物::佐久間盛政.所属上司)!=(柴田勝家)
		調査:(人物::佐久間盛政.所属上司)!=(主人公)
		調査:(人物::佐久間盛政.イベント参加可能)==(真)
		コンテナ設定:(人物,所属上司,佐久間盛政)
		コンテナ絞り込み:(人物,イベント参加可能,真)
		調査:(コンテナカウンタ)==(0)
	}
	スクリプト:{
		代入ａ:(人物::佐久間盛政.武士勲功)
		人物解雇:(佐久間盛政,京の町,出現済み)
		更新:(人物::佐久間盛政.武士勲功)(ａ)
		人物登用:(佐久間盛政,陪臣,柴田勝家)
		更新:(人物::佐久間盛政.武士勲功)(ａ)
	}
}

イベント:史実イベント発生補助{
	属性:一度だけ
	発生契機:ゲームスタート時
	発生条件:{
	}
	スクリプト:{
		ナレーション選択:[[史実イベント発生補助を行いますか？]]
		選択:[[はい]][[いいえ]]
		分岐:([[はい]]){
			更新:(イベントフラグ::史実イベント発生補助ＯＮ)(成立)
		}
	}
}

}