太閤立志伝５イベントソース
//１行目に「太閤立志伝５イベントソース」と必ず入れる

チャプター:{
	イベント:梟雄{
		属性:何度でも
		発生契機:評定開始時(無効)
		発生条件:{
調査:(主人公.所属勢力タイプ)==(大名家)
コンテナ設定:(大名家,存在,真)
コンテナソート:(大名家,支配力,降順)
コンテナ選択:(大名家Ｂ,先頭)
調査:(大名家::大名家Ｂ)==(主人公大名家)
コンテナ設定:(人物,所属大名家,主人公大名家)
コンテナ除外:(人物,人物番号,主人公)
コンテナ絞り込み:(人物,義理,不義理)
コンテナ除外:(人物,礼法技能,0)
コンテナ除外:(人物,礼法技能,1)
コンテナ除外:(人物,礼法技能,2)
コンテナ除外:(人物,礼法技能,3)
コンテナ除外:(人物,弁舌技能,0)
コンテナ除外:(人物,弁舌技能,1)
コンテナ除外:(人物,弁舌技能,2)
コンテナ除外:(人物,弁舌技能,3)
コンテナ除外:(人物,身分,足軽組頭)
コンテナ除外:(人物,身分,足軽大将)
コンテナ除外:(人物,身分,侍大将)
コンテナ除外:(人物,身分,部将)
コンテナ除外:(人物,身分,家老)
コンテナ除外:(人物,身分,大名)
コンテナ絞り込み:(人物,イベント参加可能,真)
調査:(コンテナカウンタ)>(0)
コンテナソート:(人物,野心,降順)
コンテナ選択:(人物Ａ,先頭)
調査:(人物Ａ.野心)>=(90)
代入城Ａ:(0)+(人物Ａ.所属拠点)
調査:(城::城Ａ.兵士数)>=(0)
代入大名家Ｂ:(主人公.所属大名家)
コンテナ設定:(大名家,隣接大名家(大名家Ｂ),真)
調査:(コンテナカウンタ)>=(8)
		}
		スクリプト:{
会話:(発生人物,主人公)[[では、評定を始めるといたそう]]
調査:(大名家::大名家Ｂ)==(織田信長)
調査:(大名家::大名家Ｂ.外交同盟(徳川家康))!=(同盟なし)
分岐:(真){
コンテナ除外:(大名家,大名家番号,徳川家康)
}
調査:(大名家::大名家Ｂ)==(徳川家康)
調査:(大名家::大名家Ｂ.外交同盟(織田信長))!=(同盟なし)
分岐:(真){
コンテナ除外:(大名家,大名家番号,織田信長)
}
調査:(大名家::大名家Ｂ)==(浅井長政)
調査:(大名家::大名家Ｂ.外交同盟(朝倉義景))!=(同盟なし)
分岐:(真){
コンテナ除外:(大名家,大名家番号,朝倉義景)
}
調査:(大名家::大名家Ｂ)==(朝倉義景)
調査:(大名家::大名家Ｂ.外交同盟(浅井長政))!=(同盟なし)
分岐:(真){
コンテナ除外:(大名家,大名家番号,浅井長政)
}
調査:(大名家::大名家Ｂ)==(浅井久政)
調査:(大名家::大名家Ｂ.外交同盟(朝倉義景))!=(同盟なし)
分岐:(真){
コンテナ除外:(大名家,大名家番号,朝倉義景)
}
調査:(大名家::大名家Ｂ)==(朝倉義景)
調査:(大名家::大名家Ｂ.外交同盟(浅井久政))!=(同盟なし)
分岐:(真){
コンテナ除外:(大名家,大名家番号,浅井久政)
}
コンテナ複写:(退避)
ＢＧＭ変更:(イベント危機)
条件ループ:(コンテナカウンタ)>(0){
コンテナ選択:(大名家Ａ,先頭)
代入人物Ｂ:(大名家::大名家Ａ.当主)
代入勢力Ａ:(人物Ｂ.所属勢力)//念のため確実に勢力Ａ＝大名家Ａになるように
代入勢力Ｂ:(主人公.所属勢力)//念のため
更新:(勢力::勢力Ａ.外交感情(勢力Ｂ))(絶交)
調査:(勢力::勢力Ａ.外交同盟(勢力Ｂ))==(同盟)
分岐:(真){
ＳＥスタート:(忍者報告)
会話:(忍者,発生人物)[[申し上げます！<人物Ａ>さまが\n勝手に<勢力Ａ>との同盟を\n破棄してしまいました！]]
代入ａ:(勢力::勢力Ａ.大義名分(勢力Ｂ))+(6)
更新:(勢力::勢力Ａ.大義名分(勢力Ｂ))(ａ)
}
分岐:(偽){
	調査:(勢力::勢力Ａ.外交同盟(勢力Ｂ))!=(同盟なし)
	分岐:(真){
	ＳＥスタート:(忍者報告)
	会話:(忍者,発生人物)[[申し上げます！<人物Ａ>さまが\n勝手に<勢力Ａ>との関係を\n破棄してしまいました！]]
	代入ａ:(勢力::勢力Ａ.大義名分(勢力Ｂ))+(6)
	更新:(勢力::勢力Ａ.大義名分(勢力Ｂ))(ａ)
	}
	分岐:(偽){
		条件ブロック:(勢力::勢力Ａ.大義名分(勢力Ｂ))==(0){
		ＳＥスタート:(忍者報告)
		会話:(忍者,発生人物)[[申し上げます！<人物Ａ>さまが\n勝手に<勢力Ａ>に\n宣戦布告してしまいました！]]
		}
	}
}
更新:(勢力::勢力Ａ.外交同盟(勢力Ｂ))(同盟なし)
代入ａ:(勢力::勢力Ａ.大義名分(勢力Ｂ))+(6)
更新:(勢力::勢力Ａ.大義名分(勢力Ｂ))(ａ)
コンテナ選抜:(削る,1)
}
代入拠点Ａ:(人物Ａ.所属拠点)
独立:(人物Ａ,城Ａ,通常)
会話:(忍者,発生人物)[[申し上げます、<拠点Ａ>の城主\n<人物Ａ>殿が当家に対し\n謀反を起こし、独立した模様！]]
代入勢力Ｃ:(人物Ａ.所属勢力)
更新:(勢力::勢力Ｂ.大義名分(勢力Ｃ))(60)
コンテナ複写:(復帰)
条件ループ:(コンテナカウンタ)>(0){
コンテナ選択:(大名家Ａ,先頭)
代入人物Ｂ:(大名家::大名家Ａ.当主)
代入勢力Ａ:(人物Ｂ.所属勢力)//念のため確実に勢力Ａ＝大名家Ａになるように
更新:(勢力::勢力Ｃ.外交同盟(勢力Ａ))(同盟)
コンテナ選抜:(削る,1)
}
ループ:{
コンテナ複写:(復帰)
コンテナ選択:(大名家Ａ,先頭)
代入人物Ｂ:(大名家::大名家Ａ.当主)
代入勢力Ｃ:(人物Ｂ.所属勢力)//念のため確実に勢力Ａ＝大名家Ａになるように
コンテナ選抜:(削る,1)
調査:(コンテナカウンタ)==(0)
ブロック脱出:(真)
コンテナ複写:(退避)
	条件ループ:(コンテナカウンタ)>(0){
	コンテナ選択:(大名家Ａ,先頭)
	代入人物Ｂ:(大名家::大名家Ａ.当主)
	代入勢力Ａ:(人物Ｂ.所属勢力)//念のため確実に勢力Ａ＝大名家Ａになるように
	更新:(勢力::勢力Ｃ.外交同盟(勢力Ａ))(同盟)
	コンテナ選抜:(削る,1)
	}
}
代入大名家Ａ:(人物Ａ.所属大名家)
更新:(大名家::大名家Ａ.戦略)(大名攻略)
更新:(大名家::大名家Ａ.戦略ターゲット)(大名家::大名家Ｂ.大名家番号)
会話:(忍者,発生人物)[[<人物Ａ>の働きかけにより\n当家に対する包囲網が結成されました！]]
会話:(発生人物,忍者)[[なんということだ…\nおのれ(人物Ａ.名)！]]
調査:(大名家::大名家Ｂ.戦略)!=(天下統一)
ＯＲ調査:{
調査:(大名家::大名家Ｂ.戦略)!=(地方統一)
調査:(大名家::大名家Ｂ.戦略ターゲット)!=(城::城Ａ.所在地方)
}
分岐:(真){
更新:(大名家::大名家Ｂ.戦略)(大名攻略)
更新:(大名家::大名家Ｂ.戦略ターゲット)(大名家::大名家Ａ.大名家番号)
}
条件ブロック:(発生人物)==(主人公.所属当主){
	調査:(大名家::大名家Ｂ)==(織田信長)
	調査:(人物Ａ)==(松永久秀)
	調査:(アイテム::古天明平蜘蛛.所有者)==(松永久秀)
	分岐:(真){
	会話:(発生人物,忍者)[[(人物Ａ.名)に伝えよ！\n平蜘蛛の茶釜を寄越せ！さもなくば\n全軍をもって貴様を討ち滅ぼすと！]]
	}
	分岐:(偽){
	会話:(発生人物,忍者)[[…ええい、こうなれば許す訳にはいかぬ\n家中の諸将に伝えよ！　当家は総力を挙げて\n<人物Ａ>を討つ、とな！]]
	}
}
		}
	}
}//最後にチャプターの閉じカッコを入れる