太閤立志伝５イベントソース

//攻城戦終了後に自動的に作動します
チャプター:{
	イベント:追加進撃システム（地図形改造版）{
		属性:何度でも｜ひかえめ
		発生契機:攻城戦終了時(無効,無効,無効)
		発生条件:{
			調査:(軍団::イベント用１軍団.使用状況)==(未使用)
			調査:(軍団::軍団１.軍団長)==(主人公)
			調査:(軍団::軍団１.結果)!=(敗北)
			調査:(人物::主人公.身分)>=(城主)
			代入人物Ａ:(軍団::軍団１.武将２)
			代入城Ｅ:(拠点::発生拠点)
		}
		スクリプト:{
		会話:(人物Ａ,主人公)[[{二人称名前}、引き続き城の攻略を行いますか？]]
		会話選択:(主人公,足軽)[[そうだな…]]
		選択:[[攻略を続ける]][[城に戻る]][[敵軍勢撃破]]
	分岐:([[攻略を続ける]]){
	代入ｚ:(0)
		会話:(人物Ａ,主人公)[[して、{二人称名前}\nどの城を攻め{ます}か？]]
	ループ:{
	調査:(ｚ)==(1)
	ブロック脱出:(真)
		代入大名家Ａ:(主人公.所属大名家)
		代入拠点Ａ:(拠点::宇須岸の町)
		代入城Ｂ:(主人公拠点)
		代入城Ａ:(城Ｂ)
		コンテナ設定:(拠点,無効,無効)
		コンテナ除外:(拠点,拠点タイプ,里)
		コンテナ除外:(拠点,拠点タイプ,砦)
		コンテナ除外:(拠点,拠点タイプ,町)
		コンテナ除外:(城,所属大名家,大名家Ａ)
		コンテナ選択:(城Ａ,拠点選択)
		調査:(城Ａ)!=(城Ｂ)
	分岐:(真){
		代入大名家Ｂ:(城::城Ａ.所属大名家)
		ＯＲ調査:{
		調査:(大名家::大名家Ａ.外交同盟(大名家Ｂ))!=(同盟なし)
		調査:(大名家Ａ)==(大名家Ｂ)
		調査:(城Ａ)==(城Ｅ)
		}
		分岐:(真){
		会話:(人物Ａ,主人公)[[{二人称名前}、その城には攻め込め{ません}]]
		}
	分岐:(偽){
		調査:(大名家::大名家Ａ.外交感情(大名家Ｂ))==(絶交)
	分岐:(真){
		会話可否選択:(人物Ａ,主人公)[[<大名家Ｂ>の<城Ａ>に{なさる}か？]]
		分岐:(可){
		ひとりごと:[[出陣！]]
		軍団指令:(主人公軍団,拠点攻撃,城Ａ,無効)
		代入ｚ:(1)
	}
	分岐:(否){
		会話:(主人公,人物Ａ)[[いや、もう一度考えてみる]]
	}
		}
	分岐:(偽){
		会話可否選択:(人物Ａ,主人公)[[<大名家Ｂ>に攻め込む名分が無いよう\n{だ}が、本当に{構わぬ}か？]]
		分岐:(可){
		ひとりごと:[[これより勝ちに乗じて<城Ａ>を攻め取る！\n皆のもの、行くぞ！]]
		代入ａ:(人物::主人公.悪名)+(10)
		更新:(人物::主人公.悪名)(ａ)
		軍団指令:(主人公軍団,拠点攻撃,城Ａ,無効)
		代入ｚ:(1)
		}
		分岐:(否){
		会話:(人物Ａ,主人公)[[それが懸命{だ}…]]
		}
	}
		}
	}//続投決定

		分岐:(偽){
		会話可否選択:(人物Ａ,主人公)[[城の攻略をお止めになりますか？]]
		分岐:(可){
		会話:(主人公,人物Ａ)[[{はい}、城に引き上げ{ます}ぞ]]
		代入ｚ:(1)
		}
		分岐:(否){
		会話:(主人公,人物Ａ)[[いや、もう少し考えさせて{くれ}]]
		}
		}
	}//ループ〆
	}//攻略を続ける〆

	分岐:([[城に戻る]]){
	会話:(主人公,人物Ａ)[[いや、此度はこれまでと{いたす}]]
	会話:(人物Ａ,主人公)[[左様{です}か]]
	}

	分岐:([[敵軍勢撃破]]){
	代入勢力Ａ:(主人公.所属勢力)
	コンテナ設定:(人物,出撃フラグ,出撃中)
	コンテナ除外:(人物,所属勢力,勢力Ａ)
	コンテナソート:(人物,人物番号,昇順)
	ループ:{
	コンテナ選択:(人物Ｄ,ポインタ)
	ブロック脱出:(偽)
	コンテナ複写:(退避)
	コンテナ設定:(軍団,使用状況,使用中)
	コンテナ除外:(軍団,所属勢力,勢力Ａ)
	コンテナソート:(軍団,軍団番号,昇順)
	代入コンテナポインタ:(Ｚｅｒｏ)
		ループ:{
		コンテナ選択:(軍団Ａ,ポインタ)
		ブロック脱出:(偽)
		代入勢力Ｂ:(軍団Ａ.所属勢力)
		ＯＲ調査:{
		調査:(勢力::勢力Ａ.外交同盟(勢力Ｂ))!=(同盟なし)
		調査:(勢力Ａ.外交感情(勢力Ｂ))!=(絶交)
		}
		分岐:(偽) { 
		代入コンテナポインタ:(コンテナポインタ)+(1)
		}
		分岐:(真) {
		コンテナ除外:(軍団,軍団番号,軍団Ａ)
		コンテナソート:(軍団,軍団番号,昇順)
		代入コンテナポインタ:(Ｚｅｒｏ)
		}
		}
		コンテナソート:(軍団,軍団番号,昇順)
		代入コンテナポインタ:(Ｚｅｒｏ)
		代入ｆ:(Ｚｅｒｏ)
			ループ:{
			コンテナ選択:(軍団Ａ,ポインタ)
			ブロック脱出:(偽)
			代入人物Ｂ:(軍団Ａ.軍団長)
			調査:(人物Ｄ)==(人物Ｂ)
			分岐:(真) {
			代入ｆ:(1)
			}
			代入コンテナポインタ:(コンテナポインタ)+(1)
			}
			コンテナ複写:(復帰)
			調査:(ｆ)==(Ｚｅｒｏ)
			分岐:(真) {
			コンテナ除外:(人物,人物番号,人物Ｄ)
			コンテナソート:(人物,人物番号,昇順)
			代入コンテナポインタ:(Ｚｅｒｏ)
			}
			分岐:(偽) {
			代入コンテナポインタ:(コンテナポインタ)+(1)
			}
			}
			コンテナソート:(人物,人物番号,昇順)
			調査:(コンテナカウンタ)>(0)
			分岐:(真){
			会話:(人物Ａ,主人公)[[どの軍団を目標と{いたす}か？]]
				コンテナ選択:(人物Ｅ,人物選択)
				分岐:(真) {
				代入勢力Ｂ:(人物Ｅ.所属勢力)
				会話可否選択:(人物Ａ,主人公)[[<勢力Ｂ>の<人物Ｅ>軍団に{なさる}か？]]
						分岐:(可) {	
							ひとりごと:[[出陣！]]
							コンテナ設定:(軍団,使用状況,使用中)
							コンテナソート:(軍団,軍団番号,昇順)
							代入コンテナポインタ:(Ｚｅｒｏ)
							ループ:{
								コンテナ選択:(軍団Ａ,ポインタ)
								ブロック脱出:(偽)
								調査:(軍団Ａ.軍団長)==(人物Ｅ)
								分岐:(真) {
									代入軍団Ｂ:(軍団Ａ)
									}
								代入コンテナポインタ:(コンテナポインタ)+(1)
								}
							軍団指令:(主人公軍団,軍団攻撃,軍団Ｂ,無効)
							代入ｙ:(1)
							}
						分岐:(否) {	
							}
					}
				分岐:(偽){
					}
				}
			分岐:(偽){
			会話:(足軽,主人公)[[{二人称名前}\n今のところ敵軍団の報告は{ない}]]
				}
}//軍勢撃破終了
		}//スクリプト〆
	}//イベント〆
}//チャプ〆